# This gnuplot file needs to have two filenames defined:
# one for the summary file, the other one for the source file.

# For debugging: uncomment the following two for explicit file names.
# outfilename="overview.png"
# src='summaryfile'

# Define the output format and size of the resulting graphic
set terminal png  medium size 800,400
set output outfilename

# define time format for input
set xdata time
set timefmt "%m/%d/%y"

# This is the source file plus a filter for the last n entries
s1='< grep AHU1 '.src
s2='< grep AHU2 '.src
s3='< grep AHU3 '.src
s4='< grep AHU4 '.src
s6='< grep AHU6 '.src
sp2='< grep PCW2 '.src

# key position
set key inside reverse bottom left

# axes index formats
set format x "%m/%y"
set ylabel "Removed heat (kWh)"
set xlabel "Month"
set grid xtics ytics

# set lower limit to 0
set yrange [0:*]

# Do the actual plot
plot s1 using 2:7 w l lw 2 lc rgb "#d8d800" title "AHU1", \
     s2 using 2:7 w l lw 2 lc rgb "#d000d0" title "AHU2", \
     s3 using 2:7 w l lw 2 lc rgb "#00ffff" title "AHU3", \
     s4 using 2:7 w l lw 2 lc rgb "#00ff00" title "AHU4", \
     s6 using 2:7 w l lw 2 lc rgb "#c0c0c0" title "AHU6", \
     sp2 using 2:7 w l lw 2 lc rgb "#e00000" title "PCW2"