set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,6cm 

#set terminal pngcairo enhanced font "Helvetica,48pt" size 4000,3000

set output "multiplot_powerfwhm.eps"

set multiplot

set format x "%2.0f"
set format y "%2.0f"
set yr [-1:32]
set ytics 10
set xr [0:60.5]
set xtics (0,10,20,30,40,50,60)
set tics scale 1
set tics nomirror
set border linewidth 1


# bottom figure: Spectral FWHM trace
set origin 0,0
set size 1.0,0.58

set xlabel "Injection current (mA)"
set ylabel "Spectral width (nm)" offset -0.5,0

# plotting
set arrow 1 from 33,32 to 33,-1 dt 6 lw 2 lc rgb 'black' filled nohead
set arrow 2 from 32,11 to 1,11 lw 2 lc rgb 'black' filled head
set arrow 3 from 34,11 to 59,11 lw 2 lc rgb 'black' filled head
set label 1 at 8,14 "Subthreshold"
set label 2 at 40,14 "Suprathreshold"
set samples 1000
plot 'fwhm.txt' using 1:2 notitle with points ps 1 lw 2 pt 64 lc rgb "red"

unset xlabel
unset arrow
unset label
set format x ""


# top figure: Power trace
set origin 0,0.46
set size 1.0,0.54

set log y 10
set format y "10^{%T}"
set yr [0.5:20000]
set ytics (1,10,100,1000,10000)
set ylabel "Power ({/Symbol m}W)" offset -0.5,0

# plotting
set arrow 4 from 33,20000 to 33,0.5 dt 6 lw 2 lc rgb 'black' filled nohead
set arrow 5 from 32,200 to 1,200 lw 2 lc rgb 'black' filled head
set arrow 6 from 34,200 to 59,200 lw 2 lc rgb 'black' filled head
set label 1 at 8,75 "Subthreshold"
set label 2 at 40,75 "Suprathreshold"
set samples 1000
plot 'power.txt' using 1:3 notitle with points ps 1 lw 2 pt 64 lc rgb "red"

unset multiplot

reset