# type the following command in gnuplot, in the directory that contains the .gnu and .txt datafile, as below:
# load "PSF.gnu"

# use this setting for .eps, common choice for use in LaTeX
set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,6cm 

# use this for .png, everyday use easier to open
# set terminal pngcairo enhanced font "Helvetica,24pt" size 1920,1080

# common formatting settings
set format x "%2.0f"
set format y "%2.1f"
set tics scale 2
set tics nomirror
set xrange [-400:400]
set xtics 100
set mxtics 2
set yrange [-0.05:1.05]
set ytics 0.2
set mytics 2
set border linewidth 2
set xlabel "Angle from On-Axis (milli-arcseconds)"
set ylabel "Amplitude"


# PSF of star 6mas, planet 10% obstruction, combined, using 1-m aperture diameter

set output 'before.eps'
plot 'PSF.txt' using 1:2 w l lc rgb "black" lw 2 title 'Star of 6 mas angular diameter PSF', 'PSF.txt' using 1:3 w l lc rgb "blue" lw 2 title 'Exoplanet of 10% obstruction PSF', 'PSF.txt' using 1:4 w l lc rgb "red" lw 2 title 'Output 1-m aperture, 3 mas off-axis PSF'



# 50% of PSF combined, 50% inversion, dark port output, compare areas under the curve for signal to noise ratio gain

set output 'after.eps'
set multiplot
set yrange [-0.05:0.5]
set ytics 0.1

plot 'PSF.txt' using 1:(0.5*$4) w l lc rgb "black" lw 2 title '50% input PSF', 'PSF.txt' using 1:(0.5*$5) w l lc rgb "blue" lw 2 dt 2 title '50% inversion PSF', 'PSF.txt' using 1:6 w l lc rgb "red" lw 2 title 'Dark port output after interference'

set origin 0.12, 0.5
set size 0.3, 0.35
set xr [-20:20]
set yr [0.42:0.455]
set xtics 10
set ytics 0.01
set ticscale 1
set format y "%2.2f"
unset xlabel
unset ylabel

set arrow 1 from 39.5,0.46 to 39.5,0.468 lw 2 lc rgb 'black' dt 2 nohead
set arrow 2 from 39.5,0.468 to 48,0.468 lw 2 lc rgb 'black' dt 2 nohead
set arrow 3 from 48,0.468 to 48,0.46 lw 2 lc rgb 'black' dt 2 nohead
set arrow 4 from 48,0.46 to 39.5,0.46 lw 2 lc rgb 'black' dt 2 nohead
set arrow 5 from 39.5,0.468 to -20,0.455 lw 2 lc rgb 'black' dt 2 nohead
set arrow 6 from 48,0.46 to 20,0.42 lw 2 lc rgb 'black' dt 2 nohead

plot 'PSF.txt' using 1:(0.5*$4) w l lc rgb "black" lw 1 notitle, 'PSF.txt' using 1:(0.5*$5) w l lc rgb "blue" lw 1 dt 2 notitle 

unset multiplot

reset