set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,9cm
set output "transmission.eps"

set multiplot

# common settings
# set tics scale 1

# top figure: grating

set origin 0,0.53
set size 1,0.45
set format y "%g" 
set ytics 5 
set yrange [-1:16]
set yl "Transmission [%]" offset 0.5,0
set format x2 "%2.1f"
set x2r [-0.5:0.5]
set x2tics 0.1 nomirror
set x2l "{/Symbol Dl} [nm]" offset 0,-0.3

set xr [-0.5:0.5]
unset xtics

grating(x) = a*exp(-((x-b)*(x-b))/(2*c*c))+d 
fit grating(x) "grating.dat" using 1:2:3 via a, b, c, d

set arrow 1 from -0.12,7.5 to -0.07,7.5
set arrow 2 from 0.12,7.5 to 0.07,7.5
set label 1 "0.12 nm" at 0.15,7.5

plot "grating.dat" w p ps 1 pt 7 lc -1 lw 2 notitle, grating(x) w l lt 1 lc 1 lw 2 notitle

set format x2 ""
set format x ""
# unset x2label
# unset x2tics

# bottom figure = half mm etalon

unset label 1
unset arrow 1
unset arrow 2
set log y 10
set format y "10^{%T}"
set ytics "10^{%T}"
set yr [1000:400000]
set yl "Transmitted Power" offset 0.5,0

set format x2 "%g"
set x2tics 25 nomirror
set x2r [0:-205]
set x2label "{/Symbol Dn} [GHz]" offset 0,-0.3

set format x "%g"
set xtics 5 nomirror
set xr [30:80]
set xlabel "Temperature [^{o}C]" offset 0,0.3

set origin 0,0
set size 1,0.53

set arrow from 52,200000 to 54,200000
set label "^{198}Hg" at 46,200000

set arrow from 50,30000 to 52,30000
set label "^{201}Hg" at 44,30000

set arrow from 46,8000 to 48,8000
set label "^{199}Hg" at 40,8000

set arrow from 61,30000 to 59,30000
set label "^{199}Hg" at 62,30000

set arrow from 62,15000 to 60,15000
set label "^{201}Hg" at 63,15000

set arrow from 64.5,5000 to 62.5,5000
set label "^{201}Hg" at 65.5,5000

plot "etalon_halfmm.dat" w l lt 1 lw 2 lc -1 notitle