set terminal postscript eps color enhanced font "Helvetica,16pt" size 7cm,10cm 
set output "g2trend.eps"

set multiplot

# common settings
set format y "%2.1f"
set tics scale 2
set tics nomirror
set ytics 0.1
set yr [1.525:1.875]

# bottom figure: arc g2 trace
set origin 0,0
set size 1,0.45
set format x "%2g"
set xtics 60

A(x)=a
a=1.7
set fit errorvariables
set xrange [0:90]
	FIT_LIMIT=1.e-15
	FIT_MAXITER=1000
	fit A(x) 'g2trend.txt' using 1:2:3 via a

#set label 1 "Arc" at -1.8,800

set xrange [0:360]
set xlabel "Timing [Minutes]"

set samples 1000

plot 'g2trend.txt' using ($1*4):2:3 w yerrorbars lc -1 ti "Arc",\
A(x) w l lw 2 lt 1 lc -1 notitle

unset format x ""
unset xlabel
unset xtics


# top figure: sun g2 trace
set origin 0,0.45
set size 1,0.55
set format x2 "%2g"

S(x)=s
s=1.7
set fit errorvariables
set xrange [20:70]
	FIT_LIMIT=1.e-15
	FIT_MAXITER=1000
	fit S(x) 'g2trend.txt' using 4:5:6 via s

set label "g^{(2)}({/Symbol t}=0)" at 15,1.43 rotate by 90

set x2tics 10 nomirror
set x2r [20:70]
set x2label "Elevation Angle {/Symbol a} [Degrees]"

set xtics ("5pm" 28.68, "4pm" 42.18, "3pm" 54.88, "2pm" 65.39) nomirror
set xl "Time on 28th May 2015"

set samples 1000
plot 'g2trend.txt' using 4:5:6 w yerrorbars lc 1 ti "Sun",\
S(x) w l lw 3 lt 1 lc 1 notitle



#set xdata time
#set timefmt "%H"

#plot 'g2trend.txt' using ((12+((acos(((sin(3.14159*($4)/180))-(0.3584*0.0227))/(0.9336*0.9997)))*(180/3.14159))/15)*60):5 lc -1 notitle

# a = elevation angle
# delta = declination angle = 21 degrees on 28th may 2015
# phi = latitude = +1.3 degrees north (negative for south)
# HRA = hour angle
# sin a = (sin delta)*(sin phi) + (cos delta)*(cos phi)*(cos HRA)
# sin delta = 0.3584
# sin phi = 0.0227
# cos delta = 0.9336
# cos phi = 0.9997 
# HRA = cos^-1 {[(sin a)-0.008]/0.933}