set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,6cm
set output "spectrum_arclaser_2.eps"

set multiplot

# main plot
set origin 0,0
set size 1,1

set key
# set tics scale 2
set xr [450:760]
set xl "Wavelength {/Symbol l} [nm]" offset 0,0.3
set xtics 50 
set yr [10000:12000000]
set yl "Intensity [photoevents s^{-1}]" offset 0,0
set log y 10
set format y "10^{%T}"

set label 1 "laser light" at 575,4500000 tc rgb 'blue' 
set arrow 1 from 570,4500000 to 520,4500000 filled lc rgb 'blue' front
set label 2 "blackbody radiation" at 650,1500000 tc rgb 'blue'
set arrow 3 from 645,1500000 to 625,1000000 filled lc rgb 'blue' front
set obj 1 rect from 512,1000000 to 516,12000000 back
set arrow 4 from 514,900000 to 555,300000 filled lc rgb 'black'

plot "spectrum_arclaser.txt" using 1:2 w l lw 2 lt 1 lc 1 notitle 

# inset of narrow spectral line
set origin 0.19,0.15; set size 0.45, 0.4
unset label 1
unset label 2
unset arrow 1
unset arrow 3
unset arrow 4
unset obj 1
unset ylabel
unset xlabel
set xtics 1

set xrange [512:516]; set yrange [1000000:12000000]
plot "spectrum_arclaser.txt" using 1:2 w p pt 7 ps .7 lw 2 lt 1 lc 1 notitle 

#"Simulated Laser Star"