set terminal postscript eps color enhanced font "Helvetica,20pt" size 12cm,9cm 

# common settings
set format x "%2.1f"
set format y "%2.1f"
set tics scale 2
set tics nomirror
set ytics 1000
set xtics 0.5
set ytics 0.1

set xlabel "Photoevent Separation {/Symbol t} [ns]"
set ylabel "g^{(2)}({/Symbol t})"
#set ylabel "Two-Photon Coincidences"

set output "g2_etalon_3.eps"
set yrange [0.95:1.6]
set xrange [-2:2]
set samples 1000

set label 1 "no laser" at 0.5,1.55
set label 2 "weak laser" at 0.5,1.25
set label 3 "strong laser" at 0.55,1.07

set arrow 1 from 0.45,1.55 to 0.1,1.5 lw 2 lc rgb 'red' filled front
set arrow 2 from 0.45,1.25 to 0.07,1.2 lw 2 lc rgb 'blue' filled front 
set arrow 3 from 0.5,1.07 to 0.15,1.02 lw 2 lc rgb 'black' filled front


set bars 2.5; # width of error bar ticks at ends
plot "g2_etalon.txt" every 1::125::125 using ($1)+3.8:($2)/6072:($3)/6072 w yerrorbars \
     lw 4 lc rgb 'red' lt 1 ps 1 pt 6 notitle,\
     "" every 1::126::126 using ($1)+3.8:($6)/6176:($7)/6176 w yerrorbars \
     lw 4 lc rgb 'blue' lt 1 ps 1 pt 6 notitle, \
     "" every 1::127::127 using ($1)+3.8:($8)/6241:($9)/6241 w yerrorbars \
     lw 4 lc rgb 'black' lt 1 ps .9 pt 7 notitle, \
     "" using ($1)+3.8:($2)/6072 w lines lc rgb 'red' lt 1 lw 2 notitle, \
     "" using ($1)+3.8:($6)/6176 w lines lc rgb 'blue' lt 1 lw 2 notitle, \
     "" using ($1)+3.8:($8)/6241 w lines lc rgb 'black' lt 1 lw 2 notitle



#, "" using ($1)+3.8:4:5 w yerrorbars lc 3 lt 1 ti "laser"