set terminal postscript eps color enhanced font "Helvetica,20pt" size 12cm,9cm 

# common settings
set format x "%2.1f"
set format y "%2g"
set tics scale 2
set tics nomirror
set ytics 1000
set xtics 0.5

set xlabel "Photoevent Separation {/Symbol t} [ns]"
set ylabel "Two-Photon Coincidences"

set output "g2_etalon_2.eps"
set yrange [5500:9500]
set xrange [-2:2]
set samples 1000

set label 1 "no laser" at 0.5,9000
set label 2 "weak laser" at 0.5,7300
set label 3 "strong laser" at 0.55,6600

set arrow 1 from 0.45,9000 to 0.1,8700 lw 2 lc rgb 'red' filled front
set arrow 2 from 0.45,7300 to 0.07,7000 lw 2 lc rgb 'blue' filled front 
set arrow 3 from 0.5,6600 to 0.15,6300 lw 2 lc rgb 'black' filled front


set bars 2.5; # width of error bar ticks at ends
plot "g2_etalon.txt" every 1::125::125 using ($1)+3.8:2:3 w yerrorbars \
     lw 4 lc rgb 'red' lt 1 ps 1 pt 6 notitle,\
     "" every 1::126::126 using ($1)+3.8:6:7 w yerrorbars \
     lw 4 lc rgb 'blue' lt 1 ps 1 pt 6 notitle, \
     "" every 1::127::127 using ($1)+3.8:8:9 w yerrorbars \
     lw 4 lc rgb 'black' lt 1 ps .9 pt 7 notitle, \
     "" using ($1)+3.8:2 w lines lc rgb 'red' lt 1 lw 2 notitle, \
     "" using ($1)+3.8:6 w lines lc rgb 'blue' lt 1 lw 2 notitle, \
     "" using ($1)+3.8:8 w lines lc rgb 'black' lt 1 lw 2 notitle



#, "" using ($1)+3.8:4:5 w yerrorbars lc 3 lt 1 ti "laser"