set terminal postscript eps color enhanced font "Helvetica,20pt" size 12cm,12cm 
set output "g2_arclaser_5.eps"

set multiplot

# for fit function, manual pivotisation
L(x)=a*5+b*(exp(-abs((2*x)/tc*10)))
	a=200 # 947 - div 5
	b=200 # 201
	tc=460 # 46 - times 10
B(x)=g*(exp(-abs((2*x)/jc*1000)))
	g=200 # 289
	jc=350 # - times 1000
C(x)=2*((b*g)**0.5)*(exp(-abs((x)/tc*10)-abs((x)/jc*1000)))

N(x)=L(x)+B(x)+C(x)


set fit errorvariables
set xrange [-2:96]
	fit N(x) 'g2_arclaser.txt' using 1:2:(sqrt($2)) via a,b,tc,g,jc

# common settings
set format y "%4g"
set format x "%4.2g"
#set tics scale 2
set tics nomirror
set format y2 "%2.1f"

# top plot: -2..35 ns
set origin 0,0.66
set size 1,0.36
g2max=2.0; g2min=0

set xrange [-2:96]
set xtics 20
set xlabel ""

set yrange [g2min*a*5:g2max*a*5]
set ytics 500
set ylabel " "

set y2r [g2min:g2max]
set y2tics 0.5
set y2label "g^{(2)}({/Symbol t})" rotate by -90

set object 1 rectangle from -2,0.8*a*5 to 34, 1.9*a*5 \
fs empty border lc rgbcolor 'blue' lw 2
set arrow 4 from 10,0.8*a*5 to 10,-250 lc rgb 'blue' filled
set label 3 at graph 0.9,0.9 "(a)"

plot 'g2_arclaser.txt' using 1:($2):(sqrt($2)) w yerrorbars lc 1 ps 1 notitle,\
N(x) w l ls -1 lw 2 notitle

# middle plot: -2...34 ns
set origin 0,.3333
set size 1,.36
g2min=0.8; g2max=1.9

set xrange [-2:34]
set xtics 5
unset xlabel

set yrange [g2min*a*5:g2max*a*5]
set ytics 250
set ylabel "Two-Photon Coincidences"

set y2r [g2min:g2max]
set y2tics 0.2

#unset object 1
set object 1 rectangle from -2,1*a*5 to 2, 1.8*a*5
#unset arrow 4
set arrow 4 from -1,1*a*5 to -1,600 lc rgb 'blue' filled

#set label 2 at 3,1700 "single pivoted fit over {/Symbol t} = -2..96ns\n\n{/Symbol t}_b=49.0{/Symbol \261}2.3ns; {/Symbol t}_c=0.39{/Symbol \261}0.03ns; {{/Symbol c}^2}_r=1.26"
set label 3 at graph 0.9,0.9 "(b)"

plot 'g2_arclaser.txt' using 1:($2):(sqrt($2)) \
     w yerrorbars lc 1 ps 1 notitle,\
N(x) w l ls -1 lw 2 notitle

#  bottom plot: -1.5...1.5 ns
set origin 0,0
set size 1,.36
g2min=1; g2max=1.8

set xrange [-2:2]
set xtics 0.5
set xlabel "Photoevent Separation {/Symbol t} [ns]"

set yrange [g2min*a*5:g2max*a*5]
set ytics 250
set ylabel " "

set y2r [g2min:g2max]
set y2tics 0.2

unset object 1; unset arrow 4; unset label 2
set label 3 at graph 0.9,0.9 "(c)"

plot 'g2_arclaser.txt' using 1:($2):(sqrt($2)) \
     w yerrorbars lc 1 ps 1 notitle,\
N(x) w l ls -1 lw 2 notitle