reset
set term postscript enhanced color font "Helvetica,24pt" dashlength 2.0
set size 1,0.8
set style arrow 1 nohead lw 2 dashtype 2 lc rgb 'black'
set style arrow 2 heads lw 2 lc rgb 'black'

set output "visibility.eps"
set xrange [0:360]
set yrange [0:700]
set ylabel "Pair rate (s^-^1)"
set xlabel "Polarizer angle (degrees)"
set xtics ("0(H)" 0, "90(V)" 90, "180(H)" 180, "270(V)" 270, "360(H)" 360)

set key spacing 1 font "Helvetica, 24"
set key horiz
set key box width 1 height 0.2 opaque
set boxwidth 0.9
set key top center
set key samplen .4


#set label 1 "H" at 45, 650 tc rgb 'red'
#set label 2 "V" at 135, 650 tc rgb 'green'
#set label 3 "D" at 225, 650 tc rgb 'blue'
#set label 4 "A" at 315, 650 tc rgb 'black'

A1 = 1
B1 = 1
C1 = 1

A2 = 1
B2 = 1
C2 = 1

A3 = 1
B3 = 1
C3 = 1

A4 = 1
B4 = 1
C4 = 1

f1(x) = A1*sin(x*3.142/90) + B1*cos(x*3.142/90) + C1
f2(x) = A2*sin(x*3.142/90) + B2*cos(x*3.142/90) + C2
f3(x) = A3*sin(x*3.142/90) + B3*cos(x*3.142/90) + C3
f4(x) = A4*sin(x*3.142/90) + B4*cos(x*3.142/90) + C4

fit f1(x) 'h.dat' using ($1*2):4:4 via A1, B1, C1
fit f2(x) 'v.dat' using ($1*2):4:4 via A2, B2, C2
fit f3(x) 'p.dat' using ($1*2):4:4 via A3, B3, C3
fit f4(x) 'm.dat' using ($1*2):4:4 via A4, B4, C4

plot 'h.dat' u ($1*2):4 every 2 w p pt 4 ps 1 lc rgb 'red' title 'H', f1(x) lw 2 lc rgb 'red' notitle, \
     'v.dat' u ($1*2):4 every 2 w p pt 5 ps 1 lc rgb 'green' title 'V', f2(x) lw 2 lc rgb 'green' notitle, \
     'p.dat' u ($1*2):4 every 2 w p pt 6 ps 1 lc rgb 'blue' title 'D', f3(x) lw 2 lc rgb 'blue' notitle, \
     'm.dat' u ($1*2):4 every 2 w p pt 7 ps 1 lc rgb 'black' title 'A', f4(x) lw 2 lc rgb 'black'  notitle