#!/usr/bin/env gnuplot
set terminal postscript eps color enhanced solid font 'Helvetica,22' size 15cm,12cm fontfile "cmsy10.pfb"#20cm,16cm

#Line styles
set style line 1 pt  6 ps 1.3 lw 3 lc 'red'
set style line 2 pt  6 ps 1.3 lw 3 lc 'blue'
set style line 3 pt  7 ps 1.5 lw 3 lc 'red'
set style line 4 pt  7 ps 1.5 lw 3 lc 'blue'
set style line 5 pt  7 ps 1.5 lw 3 lc rgb '#005A32'
set style line 6 pt  6 ps 1.3 lw 3 lc rgb '#005A32'

### useful labels ###
pump2 = 'P_{776} (mW)'
# brig = 'brightness (MHz * s)^{-1}'
brig = '{/CMSY10 B} (MHz s)^{-1}'
tau ='{/Symbol t} (ns)'
eff_s = '{/Symbol h}_{s,i} (%)'
delta = '{/Symbol d} (MHz)'
lab1 = ' 30 {/Symbol m}W'
lab2 = '130 {/Symbol m}W'
lab3 = '290 {/Symbol m}W'
lab4 = '420 {/Symbol m}W'
lab5 = '580 {/Symbol m}W'
lab6 = '640 {/Symbol m}W'
spt = ' '
labss = "' 30 {/Symbol m}W' '130 {/Symbol m}W' '290 {/Symbol m}W' '420 {/Symbol m}W' '580 {/Symbol m}W' '640 {/Symbol m}W'"

set macros
YBRIG="set format y '%.1gk';set ytics 1;set ylabel font 'Helvetica,24' brig offset 0, -.25; set yrange [0:2.100]"
XBRIG="set format x '%.1gk';set xtics 1;set xlabel font 'Helvetica,24' brig offset 0, .21; set xrange [0:2.100]"
YEFF="set format y '%g';set ytics 2;set ylabel font 'Helvetica,24' eff_s; set yrange [7:17]"
YTAU="set format y '%g';set ytics 1; set ylabel font 'Helvetica,24' tau; set yrange [6:10.3]"
XTAU="set format x '%g';set xtics 1; set xlabel font 'Helvetica,24' tau; set xrange [6:10.3]"
NOXTICS = "set format x ''; unset xlabel; set xtics 10"
NOYTICS = "set format y ''; unset ylabel"
XTICS_det = "set xtics"
TMARGIN = "set tmargin at screen 0.98; set bmargin at screen 0.70"
MMARGIN = "set tmargin at screen 0.68; set bmargin at screen 0.40"
BMARGIN = "set tmargin at screen 0.38; set bmargin at screen 0.10"
LMARGIN = "set lmargin at screen 0.10; set rmargin at screen 0.38"
CMARGIN = "set lmargin at screen 0.40; set rmargin at screen 0.67"
RMARGIN = "set lmargin at screen 0.69; set rmargin at screen 0.97"

set output 'delta_table.eps'
set multiplot layout 3,3 columnsfirst
set nobars

set xrange [-18:18]#[-32:28]
@NOXTICS;@YBRIG;@TMARGIN;@LMARGIN
plot 'det_data_table.dat' u 2:($6 < 1)? ($3/1000):1/0 ls 1 notitle, '' u 2:($6 > 0)? ($3/1000):1/0 ls 2 notitle
@YTAU;@MMARGIN;@LMARGIN
plot '' u 2:($6 < 1)? $4:1/0 ls 1 notitle, '' u 2:($6 > 0)? $4:1/0 ls 2 notitle
set xlabel font "Helvetica,24" delta
unset format x
@YEFF;@BMARGIN;@LMARGIN
plot '' u 2:($6 < 1)? ($5 * 100):1/0 ls 1 notitle, '' u 2:($6 > 0)? ($5 * 100):1/0 ls 2 notitle,\
    '' u 2:($6 < 1)? ($7 * 100):1/0 ls 3 notitle, '' u 2:($6 > 0)? ($7 * 100):1/0 ls 4 notitle
unset xrange

set multiplot next
@YTAU;@NOYTICS;@NOXTICS;@MMARGIN;@CMARGIN
set xtics 1
plot '' u ($3/1000):($6 < 1)? $4:1/0 ls 1 notitle, '' u ($3/1000):($6 > 0)? $4:1/0 ls 2 notitle
@YEFF;@NOYTICS;@XBRIG;@BMARGIN;@CMARGIN
set key at screen .98, .49 reverse samplen 0 Left spacing 1.5
plot '' u ($3/1000):($6 < 1)? ($5 * 100):1/0 ls 1 t 'signal', '' u ($3/1000):($6 > 0)? ($5 * 100):1/0 ls 2 notitle,\
    '' u ($3/1000):($6 < 1)? ($7 * 100):1/0 ls 3 t 'idler', '' u ($3/1000):($6 > 0)? ($7 * 100):1/0 ls 4 notitle

set multiplot next
set multiplot next
@XTAU;@BMARGIN;@RMARGIN
# unset key
set key at screen .89, .49 reverse samplen .5
plot '' u 4:($6 < 1)? ($5 * 100):1/0 ls 1 notitle, '' u 4:($6 > 0)? ($5 * 100):1/0 ls 2 t ' ',\
    '' u 4:($6 < 1)? ($7 * 100):1/0 ls 3 notitle, '' u 4:($6 > 0)? ($7 * 100):1/0 ls 4 t ' '

unset multiplot

########
XOD_NOT="set format x '';set xtics 5; unset xlabel; set xrange [4:32]"
XOD="set format x '%g';set xtics 5; set xlabel font 'Helvetica,24' 'OD'"
YBRIG_NOT="set format y '';set ytics 100;unset ylabel; set yrange [0:300]"
YBRIG="set format y '%g'; set ylabel font 'Helvetica,24' brig offset .5, -.25"
XBRIG_NOT="set format x '';set xtics 100; unset xlabel; set xrange [0:300]"
XBRIG="set format x '%g';set xlabel font 'Helvetica,24' brig offset 0, .21"
YTAU_NOT="set format y ''; set ytics 2; unset ylabel; set yrange [5.5:18.5]"
YTAU="set format y '%g'; set ylabel font 'Helvetica,24' tau offset -.5, 0"
XTAU="set format x '%g';set xtics 2; set xlabel font 'Helvetica,24' tau; set xrange [5.5:18.5]"
YEFF_NOT="set format y ''; set ytics 2; unset ylabel; set yrange [5:19]"
YEFF="set format y '%.0s%c';set ylabel font 'Helvetica,24' eff_s offset .5, 0"

set output 'OD_table.eps'
set multiplot layout 3,3 columnsfirst
set nobars

@XOD_NOT;@YBRIG_NOT;@YBRIG;@TMARGIN;@LMARGIN
plot 'OD_data_table.dat' u 2:3 ls 5 notitle
@YTAU_NOT;@YTAU;@MMARGIN;@LMARGIN
plot '' u 2:4 ls 5 notitle
@XOD;@YEFF_NOT;@YEFF;@BMARGIN;@LMARGIN
plot '' u 2:($5 * 100) ls 5 notitle, '' u 2:($6 * 100) ls 6 notitle

set multiplot next
@YTAU_NOT; @XBRIG_NOT; @MMARGIN; @CMARGIN
plot '' u 3:4 ls 5 notitle
@YEFF_NOT; @XBRIG; @BMARGIN; @CMARGIN
plot '' u 3:($5 * 100) ls 5 notitle, '' u 3:($6 * 100) ls 6 notitle

set multiplot next
set multiplot next
set key at screen .98, .49 reverse samplen 0 Left spacing 1.5
@YEFF_NOT;@XTAU; @BMARGIN; @RMARGIN
plot '' u 4:($5 * 100) ls 5 t 'signal', '' u 4:($6 * 100) ls 6 t 'idler'

unset multiplot
unset key

################
set terminal postscript eps color enhanced solid font 'Helvetica,22' size 15cm,16.64cm#20cm,20.8cm
TMARGIN = "set tmargin at screen .9846; set bmargin at screen 0.7692"
M1MARGIN = "set tmargin at screen 0.7538; set bmargin at screen 0.5385"
M2MARGIN = "set tmargin at screen 0.5231; set bmargin at screen 0.3077"
BMARGIN = "set tmargin at screen 0.2923; set bmargin at screen 0.077"

set output 'power_table.eps'
set multiplot layout 4,3 columnsfirst
set nobars

XPOWER_NOT="set format x '';set xtics 5; unset xlabel; set xrange [-1:15]"
XPOWER="set format x '%g';set xtics 5; set xlabel font 'Helvetica,24' pump2"
YBRIG_NOT="set format y '';set ytics 1000; unset ylabel; set yrange [-50:2700]"
YBRIG="set format y '%.0s%c'; set ylabel font 'Helvetica,24' brig"
XBRIG_NOT="set format x '';set xtics 1000; unset xlabel; set xrange [-50:2700]"
XBRIG="set format x '%.0s%c';set xlabel font 'Helvetica,24' brig offset 0, .21"
YTAU_NOT="set format y ''; set ytics 5; unset ylabel; set yrange [5.5:22]"
YTAU="set format y '%g'; set ylabel font 'Helvetica,24' tau"
XTAU_NOT="set format x ''; set xtics 5; unset xlabel; set xrange [5.5:22]"
XTAU="set format x '%g'; set xlabel font 'Helvetica,24' tau offset 0, .21"
YEFFs_NOT="set format y ''; set ytics 2; unset ylabel; set yrange [6.2:19]"
YEFFi_NOT="set format y ''; set ytics 2; unset ylabel; set yrange [4:14]"
YEFFs="set format y '%.0s%c'; set ylabel font 'Helvetica,24' '{/Symbol h}_s (%)' offset 1, 0"
YEFFi="set format y '%.0s%c'; set ylabel font 'Helvetica,24' '{/Symbol h}_i (%)' offset 1, 0"

load 'mypal.pal'
# set label 1 font 'Helvetica,24' 'P_{780}'at screen .85, .96
set key maxcols 1 maxrows 8 title 'P_{780}' at screen .91, .94 reverse samplen 0 Left spacing 1.2
@XPOWER_NOT;@YBRIG_NOT;@YBRIG;@TMARGIN;@LMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 2:3 every ::t*10+1::t*10+11 ls t+3 t word(labss, t+1)
unset key
@YTAU_NOT;@YTAU;@M1MARGIN;@LMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 2:4 every ::t*10+1::t*10+11 ls t+3 notitle
@YEFFs_NOT; @YEFFs; @M2MARGIN;@LMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 2:($5 * 100) every ::t*10+1::t*10+11 ls t+3 notitle
@YEFFi_NOT; @YEFFi; @XPOWER; @BMARGIN;@LMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 2:($6 * 100) every ::t*10+1::t*10+11 ls t+3 notitle

set multiplot next
@YTAU_NOT; @XBRIG_NOT; @M1MARGIN; @CMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 3:4 every ::t*10+1::t*10+11 ls t+3 notitle
@YEFFs_NOT; @XBRIG_NOT; @M2MARGIN; @CMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 3:($5 * 100) every ::t*10+1::t*10+11 ls t+3 notitle
@YEFFi_NOT; @XBRIG; @BMARGIN; @CMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 3:($6 * 100) every ::t*10+1::t*10+11 ls t+3 notitle

set multiplot next
set multiplot next
@YEFFs_NOT;@XTAU_NOT; @M2MARGIN; @RMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 4:($5 * 100) every ::t*10+1::t*10+11 ls t+3 t 'signal'
@YEFFi_NOT;@XTAU; @BMARGIN; @RMARGIN
plot for [t=0:5] 'Power_data_table.dat' u 4:($6 * 100) every ::t*10+1::t*10+11 ls t+3 t 'idler'