set terminal postscript eps color enhanced solid font "Helvetica,22" size 15cm,17cm
set nobars
set border 3
set output 'peakrate_decaytime.eps'
set multiplot
set xtics nomirror
set ytics nomirror
set size 0.5,0.5
set origin 0,0
set yrange [0:]
set colors classic
# Quadratic fit function f(x) for peak coincidence rate as a function of optical density (x).
#f(x)=a*(x**2)

#fit f(x) 'plot_data.dat' u 2:4 via a

set xlabel font "Helvetica,24" "optical density"
set ylabel font "Helvetica,24" "pair rate r_{p} (1/s)"


plot [0:31] 'plot_data.dat' u 2:6:3:7 w xyerrorbars notitle pt 7 ps 1
#, f(x) lc rgb "blue" notitle

set size 0.5,0.5
set origin 0.5,0
set xtics nomirror
set ytics nomirror
# Fit function for g2 decay time as a function of optical density (x). 
f(x)=27/(1+a*x)

a=1

fit f(x) 'plot_data.dat' u 2:12 via a

set xlabel font "Helvetica,24" "optical density"
set ylabel font "Helvetica,24" "coherence time of heralded\nidler photons {/Symbol t_{0}} (ns)"


plot [0:31] 'plot_data.dat' u 2:12:3:13 w xyerrorbars notitle pt 7 ps 1 , f(x) lc rgb "blue" notitle

set size 0.5,0.5
set origin 0,0.5

set xlabel font "Helvetica,24" "optical density"
set ylabel font "Helvetica,24" "efficiency"
#set label 1 font "Helvetica,15" "signal heralding efficiency" at first 25, first 400
#set label 2 font "Helvetica,15" "idler heralding efficiency" at first 25, first 400

plot [0:31][0:0.26] 'plot_data.dat' u 2:($6/$8):3:(sqrt(($7/$8)**2 + ($9*$6/($8**2))**2)) w xyerrorbars title "signal heralding"  pt 5 ps 1, 'plot_data.dat' u 2:($6/$10):3:(sqrt(($7/$10)**2 + ($11*$6/($10**2))**2)) w xyerrorbars title "idler heralding" pt 7 ps 1

unset label
set size 0.5,0.5
set origin 0.5,0.5
unset label
set xlabel font "Helvetica,24" "optical density"
set ylabel font "Helvetica,24" "singles rate (1/s)"

plot [0:31] [0:53000] 'plot_data.dat' u 2:8:3:9 w xyerrorbars title "signal rate" pt 5 ps 1, 'plot_data.dat' u 2:10:3:11 w xyerrorbars title "idler rate" pt 7 ps 1