set terminal postscript eps color enhanced solid font "Helvetica,22" size 15cm,17cm
set colors classic

data = 'fwm_od.dat'
set nobars
set style line 1 pt 4 ps 2 lc 'blue' lw 5
set style line 2 pt 6 ps 2 lc 'red' lw 5
set style line 3 pt 10 ps 2 lc rgb '#006400' lw 5
set style line 4 pt 12 ps 2 lc rgb '#2F4F4F' lw 5

set border 3
set xtics nomirror
set ytics nomirror

set output 'od_rates.eps'
set multiplot layout 2,1
set lmargin 10

set yrange [0:]
set xrange [0:31]

# top plots, single rates
s(x) = 1/0.00098423 * x
i(x) = 1/0.00072826 * x
set key t l
set ylabel font "Helvetica,24" "count rate (1/s)"
unset xlabel
set format x ""
set format y '%.0s%c'
plot \
	data u 2:8:3:9 w xyerrorbars title "signal" ls 1,\
	data u 2:10:3:11 w xyerrorbars title "idler" ls 2, \
	s(x) lc 'blue' lw 5 notitle, \
	i(x) lc 'red' lw 5 notitle

# bottom plot, pair rates
unset format x
set xlabel font "Helvetica,24" "optical density"
set ylabel font "Helvetica,24" "pair rate (1/s)"
plot \
	data u 2:6:3:7 w xyerrorbars notitle ls 4

# plot of the efficiencies and coherence times
unset multiplot
set terminal postscript eps color enhanced solid font "Helvetica,22" size 15cm,8.5cm
set output 'od_eff.eps'
# set multiplot layout 2,1
set xrange [0:31]

# top plots, efficiencies
s(x) = 18.863887 * (1-exp(-x/9.45939987))
i(x) = 14.566479 * (1-exp(-x/10.9499855))
set key t l
set ylabel font "Helvetica,24" "heralded efficiency (%)"
# unset xlabel
# set format x ""
set xlabel font "Helvetica,24" "optical density"
plot \
	data u 2:($6/$8*100):3:((sqrt(($7/$8)**2 + ($9*$6/($8**2))**2))*100) w xyerrorbars title "signal"  ls 1, \
	data u 2:($6/$10*100):3:((sqrt(($7/$10)**2 + ($11*$6/($10**2))**2))*100) w xyerrorbars title "idler" ls 2, \
	s(x) lc 'blue' lw 5 notitle, \
	i(x) lc 'red' lw 5 notitle

# bottom plot, pair rates
# unset format x

# Fit function for g2 decay time as a function of optical density (x)
# f(x)=27/(1+a*x)
Tau0 = 1000/(2 * pi * 6.067)
f(x)=Tau0/(1+a*x)
a=.1
fit f(x) data u 2:12 via a

set output 'od_times.eps'
set xrange [0:]
set xlabel font "Helvetica,24" "optical density"
set ylabel font "Helvetica,24" "coherence time {/Symbol t} (ns)"
plot \
	data u 2:12:3:13 w xyerrorbars notitle ls 4, \
	f(x) lc '#006400' lw 5 notitle
	# , \
	# Tau0 ls 2 lw 5 notitle