set terminal postscript eps color solid enhanced font "Helvetica,22" size 15cm, 8.5cm
set colors classic
set output 'CAR.eps'
set nobars
set border 3
set isosamples 20,20
set samples 1000,1000

set multiplot


# Dark counts of the APDs used to detect the photons
d1=175;d2=520;

# Pairs to singles efficiency of the source.
eff1=0.175;
eff2=0.135;

# ratio of total pairs to peak coincidences in 1 ns bin
t=8.4;

# Expected g(2) as a function of pair rate x
g(x)=((((x/eff1)+d1)*((x/eff2)+d2)*30e-9)+(x))/(((x/eff1)+d1)*((x/eff2)+d2)*30e-9);

set size 1,1
set origin 0,0
set xtics 1000 nomirror
set ytics 1000 nomirror
set yrange [0:4500]
set xlabel font "Helvetica,24" "pair rate (1/s)"
set ylabel font "Helvetica,24" "Coincidence to accidental ratio (CAR)"

plot [0:4500] 'CAR_pairrate.dat' u 1:7:6 w yerrorbars notitle ps 1 pt 7 lw 2, \
    g(x) lc rgb "blue" notitle

set size 0.6,0.6
set origin 0.3,0.3

set xtics 30 nomirror #font "Helvetica,14"
set ytics 2000 nomirror #font "Helvetica,14"

unset xlabel
unset ylabel

plot [0:200] 'CAR_pairrate.dat' u 1:7:6 w yerrorbars notitle ps 1 pt 7 lw 2, \
    g(x) lc rgb "blue" notitle