#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,26" size  17cm,8.7cm
#set output "../scat_tx_res.eps"
set output '../tx_matrix_multi.eps'

f1 = '2016-08-08/scat_tx'
f2 = '2016-08-08/scat_resfreq'
f3 = 'model.dat'
f4 = '2016-08-08/tx_matrix'

set border linewidth 1.5
set border 3
set multiplot 
set nobar
unset key

##
##### tx ####
set lmargin at screen 0.65
set rmargin at screen 0.97
set bmargin at screen 0.17
set tmargin at screen 0.49
set xtics nomirror
set ytics 4 nomirror

set style fill transparent solid 0.35

#set title 'extinction'
set ylabel 'extinction (%)' #offset -1.7
set key right bottom
set yrange [10:20]
set xrange [0:550]
unset key

set xlabel 'number of scattered photons'

plot f3 u 1:4:5 with filledcurves below lc rgb 'web-blue' , f1 u 1:2:3 w ye not lt 7 lc 1

##
##### res freq ####
set lmargin at screen 0.65
set rmargin at screen 0.97
set bmargin at screen 0.58
set tmargin at screen 0.92

set ylabel 'res. freq. (MHz)'

#set xtics 25
set ytics 1
set xrange [0:550]
set yrange [45:47.5]
set xlabel ''
set xtics format ''

plot f3 u 1:2:3 with filledcurves below lc rgb 'web-blue', f2 u 1:2:3 w ye not lt 7 lc 1

##
##### res freq ####
set lmargin at screen 0.15
set rmargin at screen 0.35
set bmargin at screen 0.17
set tmargin at screen 0.91

unset style fill
set pm3d map
set palette defined (0 '#67001f',1 '#b2182b',2 '#d6604d',3 '#f4a582',4 '#fddbc7',5 '#d1e5f0',6 '#92c5de',7 '#4393c3',8 '#2166ac',9 '#053061')
set xtics 10 format '% g' offset 0,0.2
set ytics 10
set cbtics (82,90,100)
set xlabel 'rel. probe frequency (MHz)' offset 0,0.4
set ylabel 'probe time (ms)' offset -0.5,0
set cblabel 'transmission (%)'
set xrange [38:56] 
set yrange [0:39] reverse
set cbrange [82:100]
set border 15
#set colorbox user origin 0.4,0.5

splot f4 u 1:2:($3*100) not



unset multiplot   
unset output
pause -1