#!/usr/bin/gnuplot
infile1 = 'tmp'
#set terminal postscript eps color enhanced solid font "Helvetica,26" size 16cm,10cm
set term pngcairo
set output "tx_Lorentzian_Dispersion_2016_07_05.png"

tx=0.15
gamma0 = 7
x0 = 45

lorentz(x) = 1 - tx / ( 4*( (x0-x) / (gamma0) )**2 + 1 ) 

tx1=0.15
gamma1 = 7
x1 = 45
dis=0.02

lorentz_dis(x) = 1 - tx1 / ( 4*( (x1-x) / (gamma1) )**2 + 1 ) + dis * (x1-x) / ( 4*( (x1-x) / (gamma1) )**2 + 1 ) 

fit lorentz(x) infile1 u (($1-190000)/1000*2):3:4 via tx,x0,gamma0
fit lorentz_dis(x) infile1 u (($1-190000)/1000*2):3:4 via tx1,x1,gamma1,dis

set title "transmission of a faint coherent field \n probe coupled to single mode fiber"
set xlabel "detuning from bare atomic resonance (MHz)"
set ylabel 'transmission (%)'
set key right bottom
set pointsize 1.0
set xrange [26:63]
set label 1 sprintf("Lorentz+Dispersion fit:") at graph 0.02,0.45
set label 2 sprintf("tx = %.3g\n", tx1*100) at graph 0.02,0.4
set label 3 sprintf("dis = %.3g\n", dis*100) at graph 0.02,0.35
set label 4 sprintf("gamma = %.3g MHz\n", gamma1) at graph 0.02,0.3


plot infile1 u (($1-190000)/1000*2):($3*100):($4*100) w yerr ps 0.8 pt 7 lw 2 not ,  lorentz(x)*100 lc 3 lw 2 t 'lorentz' ,lorentz_dis(x)*100 lc 1 lw 2 t 'lorentz+dispersion'

unset output
pause -1