#!/usr/bin/gnuplot
# plots the tx curves, with and without atom, for both shapes @ 13.5ns

# set border linewidth 1.5
set encoding utf8

## input file ##
infile_long_dec='non_reversed_with_alternating_09_26_onwards_combined_histo_tx_2ns'
infile_long_ris='reversed_with_alternating_09_26_onwards_combined_histo_tx_2ns'
#### variables ####
timebin=2e-9
offset_tx = 879
#################

unset label                            # remove any previous labels

set terminal postscript eps color enhanced solid "Helvetica,22" size 12.6cm, 8cm
set output "residuals.eps"

set border 3 linewidth 1.5
set border 3

set nobar
set multiplot
set bmargin 4



#########################
set origin 0, 0.2
set size 0.54, 0.8
set key at graph 1.15,1 spacing 1.3 samplen 0 Left reverse

set lmargin 7
set rmargin 0

set logscale y 10

set xtics 30 nomirror format " "
set xr [-15:100]

# set ytics nomirror format " "
set yr [0.4e-5:10e-4]
set ytics scale 2.5, 1 nomirror format " "
set ytics add ("10^{-3}" 1e-3,"10^{-4}" 1e-4, "10^{-5}" 1e-5)
set mytics 10

unset xlabel
set ylabel "Coincidence probability"

plot infile_long_dec u (($2-offset_tx )):($9):($10)  with yerrorbars pt 7 ps 0.9 lc rgb "black" t "{/Times-Italic G_{f,0}}  no atom",\
infile_long_dec u (($2-offset_tx )):($5):($6) with yerrorbars pt 13 ps 0.9 lc rgb "red" t "{/Times-Italic G_{f}}  with atom"


#################################
set origin 0.48, 0.2
set size 0.54, 0.8
unset key
unset ytics

set border 3
set lmargin 5
set rmargin 3
unset xlabel
unset ylabel
set ytics scale 2.5,1 nomirror format " "
set xr [-100:1.05*15]
plot infile_long_ris u (($2-offset_tx )):($9):($10)  with yerrorbars pt 7 ps 0.9 lc rgb "black", infile_long_ris u (($2-offset_tx)):($5):($6) with yerrorbars pt 13 ps 0.9 lc rgb "red"

#################################
unset logscale y
unset mytics

set origin 0, 0
set size 0.54, 0.4

unset key
set lmargin 7
set rmargin 0
set bmargin 3

set xlabel "Time from heralding event {/Times-Italic t_i} (ns)" offset graph 0.55,-.4
set ylabel "Residuals (10^{-5})" offset graph -0.04, -.1
set ytics 1E-5 nomirror format " "
# set ytics add ("-10^{-5}" -1e-5,"0" 0, "10^{-5}" 1e-5)
set ytics add ("-1" -1e-5,"0" 0, "1" 1e-5)
set yr [-0.00001:0.00001]

set xtics 30 nomirror format "%g"
set xr [-15:100]

plot 'residuals_decay.dat' u 1:2:3  with yerrorbars pt 7 ps 0.9 lc rgb "black"

# #################################
set origin 0.48, 0
set size 0.54, 0.4

# set border 3
set lmargin 5
set rmargin 3

unset xlabel
unset ylabel

set ytics 1E-5 nomirror format " "
set yr [-0.00001:0.00001]

unset xtics
set xtics 30 nomirror
set xr [-100:1.05*15]

plot 'residuals_rise.dat' u 1:2:3  with yerrorbars pt 7 ps 0.9 lc rgb "black"