#!/usr/bin/gnuplot
# plots the tx curves, with and without atom, for both shapes @ 13.5ns

set border linewidth 1.5
set encoding utf8


## input file ##
infile_long_dec='non_reversed_with_alternating_09_26_onwards_combined_histo_tx_2ns'
infile_long_ris='reversed_with_alternating_09_26_onwards_combined_histo_tx_2ns'
#### variables ####
timebin=2e-9
offset_tx = 879
#################

unset label                            # remove any previous labels

set terminal postscript eps color enhanced solid "Helvetica,22" size 12.6cm, 8cm
set output "tx_w_wo_atom.eps"

set border 3
set nobar
set multiplot #layout 1,2

set origin 0,0
set size 0.54,1
set key at graph 1.17,1 spacing 1.3 samplen 0 Left reverse
set tmargin 1.5
set lmargin 7
set bmargin 4
set rmargin 0
set xtics nomirror

set label 1 "a" at graph 0.1,0.96 font "Helvetica-Bold,22"

set logscale y 10
set ytics scale 2.5,1 nomirror format " "
set ytics add ("10^{-3}" 1e-3,"10^{-4}" 1e-4, "10^{-5}" 1e-5)
set xr [-15:100]
#set xr [-40:100]
#set xtics 100
set yr [0.4e-5:10e-4]
set mytics 10
set xtics 30
#set xlabel "Time (ns)" offset graph 0.75,0
#set xlabel "Detection time delay (ns)" offset graph 0.65,0 # {/Symbol D}t_{hb} 
set xlabel "Time from heralding event {/Times-Italic t_i} (ns)" offset graph 0.55,0 # 
set ylabel "Coincidence probability" #( x 10^{-5} )
#set ylabel "Detection rates" offset graph -0.02,0
unset bars
plot infile_long_dec u (($2-offset_tx )):($9):($10)  with yerrorbars pt 7 ps 0.9 lc rgb "black" t "{/Times-Italic G_{f,0}} , no atom",\
infile_long_dec u (($2-offset_tx )):($5):($6) with yerrorbars pt 13 ps 0.9 lc rgb "red" t "{/Times-Italic G_{f}}   , with atom"


#################################
set origin 0.48,0
set size 0.54,1
unset key
set border 3
set lmargin 5
set rmargin 3

set label 1 "b" at graph 0.12,0.96 font "Helvetica-Bold,22"


unset xlabel
unset ylabel
unset ytics
set ytics scale 2.5,1 nomirror format " "
set xr [-100:1.05*15]
#set xtics 75 nomirror
plot infile_long_ris u (($2-offset_tx )):($9):($10)  with yerrorbars pt 7 ps 0.9 lc rgb "black", infile_long_ris u (($2-offset_tx)):($5):($6) with yerrorbars pt 13 ps 0.9 lc rgb "red"


unset multiplot                     # exit multiplot mode (prompt changes back to 'gnuplot')

unset output

#pause -1