#!/usr/bin/gnuplot
# Plots the "missing" time-integrated transmission = extinction for varying photon bandwidth
#set terminal qt size 550,362 enhanced font 'Arial,18' persist
# Line width of the axes
set border linewidth 1.5


## input file ##
infile_extinction_theory='data_fig_4/Extinction_model_eta0.03'
infile_extinction_theory_high='data_fig_4/Extinction_model_eta0.031'
infile_extinction_theory_low='data_fig_4/Extinction_model_eta0.029'
infile_extinction_data_decaying='data_fig_4/extinction_data_summary_decaying'
infile_extinction_data_rising='data_fig_4/extinction_data_summary_rising'

#################
unset log                              # remove any log-scaling
unset label                            # remove any previous labels
#set key off

set terminal postscript eps color enhanced solid font "Helvetica,22" size 12.6cm,8cm
set output "fig4.eps"

set ytics 1 nomirror format "%g" 
set yr [0.0:4.95]
set xtics autofreq nomirror
set xr [1.5:6.5]
#set xr [4:14]
set xlabel "Relative bandwidth {/Symbol G}_p / {/Symbol G}_0"
set ylabel "Extinction (%)"
set border 3
unset grid
unset bars
plot  "< paste data_fig_4/Extinction_model_eta0.029 data_fig_4/Extinction_model_eta0.031" using ($1):($2*100):($4*100) with filledcurves below lc rgb "grey" t '', \
infile_extinction_theory u ($1):($2*100) w lines lw 3 lc rgb "blue" notitle,\
 infile_extinction_data_rising u (26.23/$1):((1-$3)*100):((26.23/$1)*($2/$1)):($4*100) w xyerrorbars pt 6 ps 2 lc rgb "black" lw 3 t "rising exp",\
 infile_extinction_data_decaying u (26.23/$1):((1-$3)*100):((26.23/$1)*($2/$1)):($4*100) w xyerrorbars pt 7 ps 2 lc rgb "red" lw 3 t "decaying exp"



unset output

#pause -1