#!/usr/bin/gnuplot
# plots the reflection data for 13ns long exponentially decaying and rising photons
# NOTE: the runningavg thing is left here for reference. So far we are deciding not to use it...

#set terminal qt size 350,262 enhanced font 'Arial,18' persist
# Line width of the axes
set border linewidth 1.5
set encoding utf8


## input file ##
infile_reflection_decaying ='data_fig_2/non_reversed_with_alternating_09_26_onwards_combined_histo_rx_5ns'
infile_reflection_decaying_theory ='data_fig_2/decaying_exp_reflection_model_binning_5ns'
infile_reflection_rising ='data_fig_2/reversed_with_alternating_09_26_onwards_combined_histo_rx_5ns_1'
infile_reflection_rising_theory ='data_fig_2/rising_exp_reflection_model_binning_5ns'
infile_decaying_pulse='data_fig_2/decaying_exp_pulse_fewerpoints'
infile_rising_pulse='data_fig_2/rising_exp_pulse_fewerpoints'

#################

#set autoscale                        # scale axes automatically
unset log                              # remove any log-scaling
unset label                            # remove any previous labels
#set xtic auto                          # set xtics automatically
#set ytic auto                          # set ytics automatically
#set key 0.01,100
set key off

set terminal postscript eps color enhanced solid "Helvetica,22" size 12.6cm, 8cm
set output "fig2.eps"

set border 3
set nobar
set multiplot #layout 1,2
unset key

set origin 0,0
set size 0.5,1
set tmargin 1.5
set lmargin 8
set bmargin 4
set rmargin 0
set xtics nomirror
set ytics nomirror


set xr [-100:200]
set xtics 100
set ytics format "%g" 
set yr [0.0:9.2]
set ytics 2
#set xlabel "Time (ns)" offset graph 0.75,0
#set xlabel "Detection time delay (ns)" offset graph 0.65,0 # {/Symbol D}t_{hb} 
set xlabel "Time (ns)" offset graph 0.65,0 # 
set ylabel "Coincidence probability (x 10^{-7})"
unset bars
plot infile_reflection_decaying u ($2 - (881.5+11)):($5*1e7):($6*1e7) w yerrorbars pt 6 lc rgb "red" lw 2, infile_reflection_decaying_theory u ($1):2 w lines lt 1 lc rgb "web-blue" lw 2.5
#set style fill transparent solid 0.65 noborder
#plot infile_reflection_decaying u 2:($5*1e7):(5):($6*1e7) w boxxy lc rgb "grey", "" u 2:($5*1e7) w p pt 7 ps 0.7 lc rgb "red" lw 2, infile_reflection_decaying_theory u ($1):2 w lines lt 1 lc rgb "web-blue" lw 2.5


set origin 0.27,0.63
set size 0.22,0.38
unset ylabel
unset xlabel
set xr [-0.3:1.5]
set yr [0:1]
unset xtics
#set xtics (0) offset -0.1,0.4 font "Helvetica,18"
unset border
unset ytics
set label 1 "{/Symbol x}" at -0.8,0.5
set label 2 "t" at 1.6,0 font "Helvetica-Italic,18"
set label 3 "0" at -0.15,-0.25 font "Helvetica,18"

#set style arrow 1 head filled size screen 0.005,40,40
#set arrow 1 from -0.85,0.4 to -0.85,0.1 as 1

set style arrow 1 lw 1.2 head filled size screen 0.01,15
set arrow 1 from -0.3,0 to 1.5,0 as 1 
set arrow 2 from -0.3,0 to -0.3,1.2 as 1

plot infile_decaying_pulse u ($1*1e7):($2*1e-4) w l lc rgb "blue" lw 2

#################################
set origin 0.5,0
set size 0.5,1
set border 3
set lmargin 5
set rmargin 3
unset ytics
#unset ylabel
#unset xlabel
#unset bars
unset label 1
unset label 2
unset label 3
unset arrow 1
unset arrow 2
set xr [-150:150]
set yr [0.0:9.2]
set xtics 75 nomirror
plot infile_reflection_rising u ($2- (878.5+11)):($5*1e7):($6*1e7) w yerrorbars pt 6 lc rgb "red" lw 2, infile_reflection_rising_theory u ($1):2 w lines lt 1 lc rgb "web-blue" lw 2.5 
#plot infile_reflection_rising u 2:($5*1e7):(5):($6*1e7) w boxxy lc rgb "grey", "" u 2:($5*1e7) w p pt 7 ps 0.7 lc rgb "red" lw 2, infile_reflection_rising_theory u ($1):2 w lines lt 1 lc rgb "web-blue" lw 2.5


set origin 0.77,0.63
set size 0.22,0.38
unset ylabel
unset xlabel
set xr [-1.3:0.3]
set yr [0:1]
unset xtics
unset ytics
#set xtics (0) offset -0.1,0.4 font "Helvetica,18"
set border 2 lw 1
unset ytics
set label 1 "{/Symbol x}" at -1.8,0.5
set label 2 "t" at 0.65,0 font "Helvetica-Italic,18"
set style arrow 1 lw 1.2 head filled size screen 0.01,15
set label 3 "0" at -0.15,-0.25 font "Helvetica,18"

set arrow 1 from -1.3,0 to 0.55,0 as 1 
set arrow 2 from -1.3,0 to -1.3,1.2 as 1
plot infile_rising_pulse u ($1*1e7):($2*1e-4) w l lc rgb "blue" lw 2


unset multiplot                     # exit multiplot mode (prompt changes back to 'gnuplot')




#replot
unset output

pause -1