reset

set term postscript enhanced eps color size 8.6cm,6cm font "Helvetica,16pt"
set output 'multiplot.eps'
set multiplot

#graph b - point distribution
set size 0.6,1
set origin 0,0
set rmargin 0

unset ytics
set ytics ("-2^{15}" -32767, "2^{15}-1" 32768)
set xtics (0,50,100,150,200)

unset key
set yrange[-40000:40000]
set xrange[0:250]

set xlabel "Time ({/Symbol m}s)"
set ylabel 'ADC value' offset 4.5,0

plot 'scrambled.txt' using ($1*0.05):2 w p \
     pt 1 ps 0.1 lc rgb 'red' title 'processed numbers',\
     'new_raw_sequence.txt' using ($1*0.05):($2-32767) w p \
     ps 0.1 lc rgb 'blue' title 'biased numbers'


# graph a - histogram
set size 0.4,1
set origin 0.6,0
set format y ""
set rmargin 1; set lmargin .5

unset ylabel
unset ytics

set key samplen 1.5

set yrange[-40000:40000]
set xrange[0:700]
set xtics (0,200,400,600)

set xlabel 'Counts' 

unset bars
plot "scrambledhisto.txt" u ($2/2):1:($2/2) w xerrorbars \
     lt 1 ps 0 lc rgb"red" title "extracted data",\
     "new_raw_histo.txt" u ($2/2):($1-32767):($2/2) w xerrorbars \
     lt 1 ps 0 lc rgb"blue" title "raw data"