reset

set term postscript enhanced eps color size 11.69in,8.27in linewidth 3
set term postscript landscape
set output 'distribution.eps'

f(x) = a*exp((-(x-b)**2)/(c**2))
g(x) = d*exp((-(x-e)**2)/(f**2))

a = 0.05
b = 60
c = 1
d = 0.1
e = 60
f = 0.5

set noytics
set noxtics


#set style arrow 3 nohead
set style fill transparent solid 0.2 border lc rgb 'white'

set xrange[-80:80]
#plot f(x), 'distribution_ele.txt' using 1:2
fit f(x) 'distribution_vac.txt' using 1:2 via a,b,c
fit g(x) 'distribution_ele.txt' using 1:2 via d,e,f

set multiplot layout 3, 1
set lmargin at screen 0.05
set tmargin at screen 0.95
set bmargin at screen 0.7

#plot1
unset key
set style arrow 8 heads size screen 0.008,90 lc rgb 'black' lw 1
set arrow from 0,0.01 to c,0.01 as 8
set yrange[0:0.05]
set ylabel "{P_t}(x)" font "Helvetica, 26" offset -1,0
#plot 'distribution_vac.txt' using ($1)-b:2 with boxes lc rgb 'blue', f(x+b) w l lw 1 lc rgb 'red'
set label "{{/Symbol s}_t}" at 18,0.015 font "Helvetica, 26" 
plot f(x+b) w l lw 1 lc rgb 'red'


#plot2
unset key
unset arrow
set tmargin at screen 0.65
set bmargin at screen 0.4
set style arrow 8 heads size screen 0.008,90 lc rgb 'black' lw 1
set arrow from 0,0.025 to f,0.025 as 8
unset label
set label "{{/Symbol s}_e}" at 10,0.04 font "Helvetica, 26"
set yrange[0:0.16]
unset ylabel
set ylabel "{P_e}(x)" font "Helvetica, 26" offset -1,0
set samples 1000
#plot 'distribution_ele.txt' using ($1)-e:2 with boxes lc rgb 'blue', g(x+e) w l lw 1 lc rgb 'red'
plot g(x+e) w l lw 1 lc rgb 'red'

#plot3
unset key
unset arrow
set tmargin at screen 0.35
set bmargin at screen 0.1
set xlabel 'x' font "Helvetica, 26" offset 40,0
set style arrow 8 heads size screen 0.008,90 lc rgb 'black' lw 1
set arrow from 0,0.008 to sqrt(c**2-f**2),0.008 as 8
unset label
set label "{{/Symbol s}_q} = ({{{/Symbol s}_t}^2} - {{{/Symbol s}_e}^2})^{1/2}" at 16,0.015 font "Helvetica, 26"
set yrange[0:0.05]
unset ylabel
set ylabel "{P_q}(x)" font "Helvetica, 26" offset -1,0
plot (1/(2.507*sqrt(c**2-f**2)))*exp((-(x)**2)/(c**2-f**2)) lw 1 lc rgb 'blue'