# script to plot the scattering angle as a function of the normalized
# impact parameter:

set terminal postscript eps color enhanced size 10cm,6cm font "Times-Roman,24pt" dashlength 2.0
set output 'rutherford1.eps'


set border 0
unset y2tics
unset x2tics


phi(x)=2*atan(1/x)

set xrange [0:8]
set yrange [-4:4]


set ytics ("-{/Symbol p}" -pi, "-{/Symbol p}/2" -pi/2, "0" 0, \
    "{/Symbol p}/2" pi/2 , "{/Symbol p}" pi ) axis
unset xtics

set label 1 "{/Symbol j}'" at -.8,4
set label 2  "{/Times-Italic b} / {/Times-Italic b}_0" at 7.5,-1

set arrow from 0,0 to 8.5,0 filled
set arrow from 0,-4 to 0,4 filled 

set arrow from 1,0 to 1,pi/2 nohead lt 2 lc rgb 'black'
set arrow from 1,pi/2 to 0, pi/2 nohead lt 2 lc rgb 'black'

set arrow from 1,-.2 to 1,.2 nohead
set label 3 "1" at .9,-.6

set label 4 "{/Times-Italic k} > 0 (attractive potential)" at 2,-1.8
set label 5  "{/Times-Italic k} < 0 (repulsive potential)" at 2,1.8


plot phi(x) lt 1 lc rgb 'red' lw 3 notitle, \
      -phi(x) lt 2 lc rgb 'red' lw 3 notitle