# code to generate the plot for an effective potential

set terminal postscript eps enhanced color font "Times-Italic,24pt" size 12cm,6cm dashlength 2
set output 'effectivepotential.eps'

set border 0

k=.18; l=0.1

U(x)=-k/x
W(x)=l**2/x**2
V(x)=U(x)+W(x)

set size 0.9,1; set origin 0.1,0

set xrange [0:1]
set yrange [-1:1]
set format x ""
set format y ""
unset xtics
unset ytics
set xzeroaxis
set arrow from 0,-1 to 0,1.05 filled
set arrow from 0,0 to 1.02,0 filled
set ylabel " " offset -1 
set label 1 "V_{/Times-Roman eff}" at -0.1,0.9
set label 2 "r" at 1.03,-0.05

set arrow from 0,0.5 to 0.9,0.5 lt 3 lw 1 lc rgb 'black' nohead
set arrow from 0.05,0.5 to 0.9,0.5 lt 1 lw 4 lc rgb 'black' nohead

set arrow from 0,-0.5 to 0.9,-0.5 lt 3 lw 1 lc rgb 'black' nohead
set arrow from 0.07,-0.5 to 0.29,-0.5 lt 1 lw 4 lc rgb 'black' nohead

set arrow from 0,-0.81 to 0.9,-0.81 lt 3 lw 1 lc rgb 'black' nohead

set label 3 "E_{/Times-Roman 1}" at -.08,-.81
set label 4 "E_{/Times-Roman 2}" at -.08,-.51
set label 5 "E_{/Times-Roman 3}" at -.08,.49

set arrow from 0.11,-0.81 to 0.11,-0.88 lt 1 lw 1 lc rgb 'black' nohead
set label 6 "r_{/Times-Roman 1}" at .09,-.95

set arrow from 0.11,-0.38 to 0.08,-0.48 lt 1 lw 1 lc rgb 'black' filled
set arrow from 0.25,-0.38 to 0.28,-0.48 lt 1 lw 1 lc rgb 'black' filled

set label 7 "r_{/Times-Roman 2 min}" at .08,-.28
set label 8 "r_{/Times-Roman 2 max}" at .22,-.28


set arrow from 0.09,0.6 to 0.06,0.52 lt 1 lw 1 lc rgb 'black' filled
set label 9 "r_{/Times-Roman 3 min}" at .08, .68

set label 10 "l^2/(2{/Symbol m}r^2)" at .13,.95
set label 11 "U(r)" at .33,-.65
set label 12 "V_{/Times-Roman eff}(r)" at .07,.15

set label 13 "{/Times-Roman 0}" at -.06,0

plot U(x) w l lt 2 lw 3 lc rgb 'red' notitle,\
     W(x) w l lt 2 lw 3 lc rgb 'red' notitle,\
     V(x) w l lt 1 lw 6 lc rgb 'blue' notitle