# script to plot the dispersion relation of a linear chain

set terminal postscript eps color enhanced size 12cm,8cm \
font "Times-Italic,24pt" dashlength 2.0
set output 'dispersionrelation.eps'
set multiplot 
set size 0.9,1
set origin 0.05,0

N=10
yma=1.1

set border 0
set xrange [0:1]
set x2range[0:N+1]
set xtics (0, "{/Symbol p}/d" 1) axis
set yrange [0:yma]
set x2tics (0, "{/Symbol p}/d" N+1.5) 
unset ytics
set x2tics ("" 0, 1, 2, "..." 3, "" 4, "" 5, "" 6, "" 7, "" 8, "N-1" 9, "N" 10, \
"" 11) border out
set grid x2
set arrow 1 from 0,0 to 1.1,0 filled
set arrow 5 from 0,yma to 1.1,yma filled
set arrow 2 from 0,0 to 0,yma+0.15 filled

set label 1 "{/Symbol w}_r" at -.1,1.2
set label 2 "r" at 1.05,1.15
set label 6 "q" at 1.05,-.05
set label 7 "{/Symbol w}_{/Times-Roman max}" at -.1,1

set arrow 3 from 0,1 to 1,1 nohead lt 2 lc 'black' lw 0.5
set arrow 4 from 1,0 to 1,1 nohead lt 2 lc 'black lw 0.5

plot sin(x*pi/2) lt 2 lw 0.5 lc rgb 'red' notitle, \
     '-' using ($1/(N+1)):(sin($1*pi/(N+1)/2)) ps 1.2 pt 7 lc rgb 'blue' notitle

1
2
3
4
5
6
7
8
9
10
e