# script to plot a number of cone intersections

set terminal postscript eps color enhanced size 8cm,8cm font "Times-Roman,24pt" dashlength 2.0 
set output "coneintersections.eps"

set parametric

set format x ""
set format y ""
set border 0
unset xtics
unset ytics

set multiplot

set xrange [-9:1]
set yrange [-5:5]

alpha=1; epsilon=0;
set trange [-pi:pi]

r(t)=alpha/(1+epsilon*cos(t))
x(t)=r(t)*cos(t)
y(t)=r(t)*sin(t)

plot x(t),y(t) notitle

alpha=1.5; epsilon=0.5;
plot x(t),y(t) notitle

alpha=1.75; epsilon=0.75;
plot x(t),y(t) notitle

alpha=2; epsilon=1;
plot x(t),y(t) notitle

set trange [-4:4]
alpha=2.5; epsilon=1.5;

plot x(t),y(t) notitle

set trange [0:2.42]
plot 0.4*cos(t), .4*sin(t) lc rgb 'black' notitle

set label 10 "{/Symbol q}" at 0.3,.5

set arrow from 0,0 to -3,2.6 filled
set label 1 "{/Times-Italic r}({/Symbol q})" at -3.9,2.2

set label 2 "{/Symbol e}=0" at -2.2,0.5

set label 3 "{/Symbol e}=0.5" at -4.5,1
set label 4 "{/Symbol e}=0.75" at -8,2
set label 5 "{/Symbol e}=1" at -5,4
set label 6 "{/Symbol e}=1.5" at -.5,4

set label 7 "{/Times-Italic F}" at 0,-.5
set label 8 "{/Times-Italic P}" at 1.5,0
set label 9 "{/Times-Italic A}" at -8,0

set arrow from -7.5,0 to 1.5,0 nohead lt 2 lc rgb 'black'

unset parametric

plot '-' w p ps 1 pt 7 lc rgb 'black' notitle
1 0
0 0
-7 0
-3.1 2.65
e