set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,9cm 

#set terminal pngcairo enhanced font "Helvetica,12pt" size 1920,1080

set output "jitter.eps"
#set output "jitter.png"

#common settings
set tics scale 2
set tics nomirror
set ytics 1000
set xtics 0.5
set mytics 2
set mxtics 5
set tics scale 2
set tics nomirror

set yrange [-200:3900]
set xrange [-1:1]
set border linewidth 1
set samples 1000

set ylabel "Two-photoevent coincidences" 

gaussian(x) = base + peak*exp(-(x)**2/(2*wid**2))
peak = 3449.54323 #+/- 14.5084544 (0.42%) (init = 3452)
#cen = 237.450866 #+/- 3.3691e-04 (0.00%) (init = 237.45)
wid = 0.09942433 #+/- 2.5498e-04 (0.26%) (init = 0.099)
base = 7.17536442 #+/- 0.04196469 (0.58%) (init = 0)

set multiplot layout 2,1

set label "(a) Detector response" at screen 0.20, 0.93
set tmargin at screen 1.00
set bmargin at screen 0.56
set format x ""
plot "irf_coin_tbin8ps.txt" using ($1-237.45):2:(sqrt($2)) with yerrorbars lw 2 lc rgb "red" notitle, gaussian(x) with lines lw 2 lc rgb "black" notitle

set label "(b) Convolved g^{(2)}({/Symbol t})" at screen 0.20, 0.49
set arrow from -0.3,1.8 to -0.02,1.65 lw 1 lc rgb "black"

set label "Ideal g^{(2)}({/Symbol t})" at screen 0.68, 0.49
set arrow from 0.45,1.82 to 0.08,1.78 lw 1 lc rgb "black"

set tmargin at screen 0.56
set bmargin at screen 0.12
set lmargin at screen 0.18
set format x "%2.1f"
set ylabel "g^{(2)}({/Symbol t})" 
set xlabel "Timing separation, {/Symbol t} (ns)" 
#at screen 0.35, 0.03
set yrange [0.9:2.1]
set ytics 0.5
set mytics 5
set format y "%2.1f"

plot "irf_convolution.txt" using 1:2 with lines dt 2 lw 2 lc rgb "black" notitle,\
"irf_convolution.txt" using 1:3 with lines lw 2 lc rgb "red" notitle

unset multiplot
reset