set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,6cm 

#set terminal pngcairo enhanced font "Helvetica,12pt" size 1920,1080

# common settings
#set format y "%2.0f"
set format x "%2.1f"
set tics scale 2
set tics nomirror
set ytics 25
set xtics 0.5
set x2tics 50
set mx2tics 5
set mytics 5
set mxtics 5
set yrange [0:100]
set xrange [1570.82:1572.82] #nm
set x2range [116.4:-116.4]		#GHz
set border linewidth 1
#set bars large
#set grid

set xlabel "Wavelength {/Symbol l} (nm)"
set x2label "Relative {/Symbol D}f (GHz)"
set ylabel "Normalized transmission (%)" offset 0,0

set output "etalon.eps"
#set output "etalon.png"
set samples 1000

# Define a solid fill style (1.0 = 100% opaque solid color)
set style fill solid 1.0 noborder

#columns in spectra.txt
#1: wavelength (nm)
#2: SLD + EDFA
#3: BP
#4: E
#5: BP + E

set label "BP+E" at screen 0.715,0.81
set label "BP" at screen 0.715,0.71
set label "E" at screen 0.715,0.61

set arrow from 1572.2,92 to 1571.85,92 lw 1 lc rgb "black"
set arrow from 1572.2,78 to 1572.00,78 lw 1 lc rgb "black"
set arrow from 1572.2,64 to 1572.12,64 lw 1 lc rgb "black"


plot "spectra.txt" using 1:($3/0.000000715) with lines lw 3 lc rgb "black" notitle,\
"spectra.txt" using 1:($4/0.000000115)/($2/0.00033) with lines dt 2 lw 3 lc rgb "blue" notitle,\
"spectra.txt" using 1:($5/0.000000034) with filledcurves x1 lc rgb "red" notitle


reset