set terminal postscript eps color enhanced font "Helvetica,16pt" size 8.6cm,9cm 

#set terminal pngcairo enhanced font "Helvetica,12pt" size 1920,1080

set output "countrate.eps"
#set output "countrate.png"

#common settings
set tics scale 2
set tics nomirror
set ytics 5
set mytics 5
set mxtics 4
set yrange [1:16]
set border linewidth 1
set samples 10000

set label "Time (hour:minute)" at screen 0.35, 0.03
set label "Photoevent detection rate, r ({/Symbol \264}10^3 s^{-1})" at screen 0.02, 0.65 center rotate by 90

#threshold reference lines for APD dark counts, kcps
darkcountsA(x)=3.8
darkcountsB(x)=1.7

#x-axis time format to hours-minutes-seconds
set xdata time
set timefmt "%s"     

#define night's start time (in UTC-7 Unix seconds)
#Palomar local time 8pm, 2nd july 2026
start_time = 1783022400
set xrange [start_time:start_time+(10*3600)]

#handle crossing over midnight gracefully
#creates clean hourly tick marks across the date change
set xtics 7200       

#$0 is the row index (0, 1, 2...)
#($0*60) converts the row minutes to seconds


set multiplot layout 4,1

set label "4th July" at screen 0.8, 0.96
set tmargin at screen 1.00
set bmargin at screen 0.75
set format x ""
plot "AlphaHer_countrates_4th.txt" using ((35*60)+start_time+(($0-1)*60)):($2)/1000 with lines lw 2 lc rgb "black" notitle, "AlphaHer_countrates_4th.txt" using ((35*60)+start_time+(($0-1)*60)):($4)/1000 with lines lw 2 lc rgb "blue" notitle, darkcountsA(x) with lines lw 1 lc rgb "black" dt 4 notitle, darkcountsB(x) with lines lw 1 lc rgb "blue" dt 4 notitle

set label "3rd July" at screen 0.8, 0.71
set tmargin at screen 0.75
set bmargin at screen 0.50
set format x ""
plot "AlphaHer_countrates_3rd.txt" using ((41*60)+start_time+(($0-1)*60)):($2)/1000 with lines lw 2 lc rgb "black" notitle, "AlphaHer_countrates_3rd.txt" using ((41*60)+start_time+(($0-1)*60)):($4)/1000 with lines lw 2 lc rgb "blue" notitle, darkcountsA(x) with lines lw 1 lc rgb "black" dt 4 notitle, darkcountsB(x) with lines lw 1 lc rgb "blue" dt 4 notitle

set label "2nd July" at screen 0.8, 0.46
set tmargin at screen 0.50
set bmargin at screen 0.25
set format x ""
plot "AlphaHer_countrates_2nd.txt" using ((158*60)+start_time+(($0-1)*60)):($2)/1000 with lines lw 2 lc rgb "black" notitle, "AlphaHer_countrates_2nd.txt" using ((158*60)+start_time+(($0-1)*60)):($4)/1000 with lines lw 2 lc rgb "blue" notitle, darkcountsA(x) with lines lw 1 lc rgb "black" dt 4 notitle, darkcountsB(x) with lines lw 1 lc rgb "blue" dt 4 notitle

set label "Elevation ({/Symbol \\260})" at screen 0.02, 0.17 center rotate by 90
set yrange [0:75]
set ytics 20
set mytics 2
set label "{/Symbol a} Her" at screen 0.8, 0.21
set tmargin at screen 0.25
set bmargin at screen 0.10
set format x "%H:%M"
plot "AlphaHer_elevation.txt" using (start_time+(($0-1)*600)):2 with lines lw 2 lc rgb "black" notitle

unset multiplot
reset