set terminal postscript eps color enhanced solid font "Helvetica,20" size 12cm,7cm
set colorsequence classic
set output 'characterization.eps'
set multiplot layout 1, 2

infile1 = 'scattering_1us.dat'
infile2 = 'cavity_laser_scan.dat'
infile3 = 'cavity_laser_fit.dat'

unset ylabel
unset xlabel
unset key

# assuming APD efficiency of 56%, coupling of 62% and PBS loses 50%, can estimate probe power
# during the calibration, there is an OD that corresponds to 31.68x
factor = 31.68*2.548e-19*1e12/.56/.62 #pW/(cps/s)

f(x)=(f0/100)*(gamma/2)*(x/x0)/(1+(x/x0))
gamma = 38.117 #decay rate per us
f0 = 1.1
x0 = 6
fit f(x) infile1 u (factor*$2):($3/$4):(sqrt($3)/$4) yerror via f0,x0

#
set ytics .1 nomirror
set yrange [0:.37]
set xtics nomirror
set xrange[.45:2000]
set label 1 at 0.69, 0.351
set label 1 "(a)" tc lt 7
set lmargin 7
set rmargin 2
set tmargin at screen 0.98
set bmargin at screen 0.15
set ylabel "Photon Detection Rate ({/Symbol m}s^{-1})" offset 1.5,0
set xlabel "Probe Power (pW)" offset 0,0.2
set logscale x

plot infile1 u (factor*($2)):($3/$4):(factor*sqrt($2)):(sqrt($3)/$4) w xyerr lc 1 ps 0.9 pt 7 notitle, f(x) lw 3 lc 3 notitle

#
unset label 1
unset ylabel
unset xlabel
unset logscale x
set ytics 0.2 nomirror
set yrange [0:1.05]
set xtics 5 nomirror
set xrange[-12:12]
set label 2 at -10.7, 0.995
set label 2 "(b)" tc lt 7
set tmargin at screen 0.98
set bmargin at screen 0.15
set ylabel "Normalized Intensity" offset 1.5,0
set xlabel "Cavity Detuning (MHz)" offset 0,0.2
set bars 2

plot infile2 u ($1-137.77):($2/29998.87):($3/29998.87) w yerr lc 1 ps 0.9 pt 7 notitle, infile3 u ($1-137.77):($2) w lines lw 3 lc 3

unset multiplot

pause -1