#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm,6cm
set output "../tx_over_trapdepth.eps"

####GENERAL SETTINGS####
set lmargin at screen 0.16
set rmargin at screen 0.9
set border linewidth 1.5
set samples 5000
set pointsize 1
unset bar
set style fill solid 0.3 noborder
set key samplen 0.1
f0 = 'tx_over_trapdepth' # data from 2018-05-30
f1 = 'sim_tx_over_trap_depth.dat'
f2 = 'sim_res_freq_component.dat'
volt_to_trap =  1/1.46
max_tx =24.7
bfield = 14.436 #Gauss
freq_mk = 20.827 # 1mK in frequency: 1mk/hbar in MHz
ct = 0.0716 # coefficient of tensor light shift
gF = 0.93
eta0(x) = max_tx * (1 - 15/8*(x*freq_mk*ct/(bfield*gF))**2 )

blue_defined = '#0078FF'

set xtics nomirror
set ytics nomirror

set xlabel 'Trap depth (mK)'
set ylabel 'Extinction (%)'


set ytics 4
set yrange[5.5:25.5]
set xrange[0.:2.6]
set xtics 1
unset key
plot eta0(x) w l lc rgb 'black' lw 2 dt 2,\
f2 u 1:(max_tx*$2) w l lc rgb 'blue' lw 2,\
f1 u 1:(max_tx*$2) w l lc rgb 'red' lw 2,\
f0 u ($1*volt_to_trap):2:3 w ye lc rgb 'red' pt 7 lw 2

unset output