#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm,10cm
set output "../tx_matrix_revised.eps"

f1= 'tx_matrix_trap1.3_2018-05-08'
f2= 'tx_matrix_0.88mK_sim'
f3= 'tx_matrix_trap3.3_2018-05-10'
f4= 'tx_matrix_2.24mK_sim'
####GENERAL SETTINGS####
blue_defined = '#0078FF'
set border linewidth 1.5
set samples 5000
set multiplot 
set style fill solid 0.3 noborder
unset key
set tics front

volt_to_Bfield = 1.604/10 # Gauss/V (hack /10 to mT/V)
max_tx=24.7
## bottom left ##
set tmargin at screen 0.49
set bmargin at screen 0.11
set lmargin at screen 0.16
set rmargin at screen 0.44

set ytics nomirror
set xtics nomirror 
set ytics 10
set xtics 0.4
# dirty hack to set units in mT
#set xtics ("0" 0, "0.4" 4, "0.8" 8, "1.2" 12)
set ylabel 'Probe detuning (MHz)' offset 0.5,7
set cblabel 'Transmission (%)'
set yrange [-0.25:39.25] 
set xrange [-0.025:1.475] 
set cbrange [77:100]
unset colorbox

unset xlabel 
#set label 1 sprintf("U_0/k_B = 0.85mK") at graph 0.17,0.94 font "Helvetica, 14" front
set label 1 sprintf("U_0/k_B = 0.88mK") at graph 0.17,0.94 font "Helvetica, 14" front
set label 2 sprintf("(c)") at graph -0.16,1.07 font "Helvetica, 16"

plot f1 u ($2*volt_to_Bfield*0.75):($1):($3*100) matrix with image 

## bottom right ##
set lmargin at screen 0.49
set rmargin at screen 0.77
unset label 1 

set ytics format " "
set cbtics (77,90,100) offset -1,0
set xlabel 'Magnetic field (mT)' offset -7,0
set cblabel 'Transmission (%)'
 
set colorbox user origin .82,0.235 size .03,0.6
set cblabel 'Transmission (%)' offset -1.5 ,0

unset ylabel 
set label 2 sprintf("(d)") at graph -0.16,1.07 font "Helvetica, 16"

plot f2 u ($2*volt_to_Bfield*0.25):($1*0.5):(100 - $3*max_tx) matrix with image 

#################
## top left ##
set tmargin at screen 0.92
set bmargin at screen 0.54
set lmargin at screen 0.16
set rmargin at screen 0.44
unset label 1 

set xtics format " "
set ytics format "% g"

set ylabel 'Probe detuning (MHz)'
set xlabel 'Magnetic field (G)'
set cblabel 'Transmission (%)' 
set yrange [43.75:83.25] 

unset xlabel
unset ylabel
unset colorbox
#set label 1 sprintf("U_0/k_B = 2.15mK") at graph 0.17,0.94 font "Helvetica, 14" front
set label 1 sprintf("U_0/k_B = 2.24mK") at graph 0.17,0.94 font "Helvetica, 14" front
set label 2 sprintf("(a)") at graph -0.16,1.07 font "Helvetica, 16"

set title "Experiment"


plot f3 u ($2*volt_to_Bfield*0.75):($1+44):($3*100) matrix with image 


## top right ##
set lmargin at screen 0.49
set rmargin at screen 0.77
unset label 1
set ytics format " "
set xtics format " "

set xlabel 'Probe detuning (MHz)'
set ylabel 'Magnetic field (G)'
set cblabel 'Transmission (%)'
#set xrange [-0.25:14.75] 


unset xlabel
unset ylabel

set title "Simulation"
set label 2 sprintf("(b)") at graph -0.16,1.07 font "Helvetica, 16"


plot f4 u ($2*volt_to_Bfield*0.25):($1*0.5+44):(100-$3*max_tx) matrix with image 

unset multiplot   
unset output