#!/usr/bin/gnuplot

file = 'state_detection_2018-05-18_250ampunits.timestamp.dat.histo'

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm, 6cm
set termoption dash
set output "../statereadout_histo.eps"

set multiplot 
blue_defined = '#0078FF'
set border linewidth 1.5

set xrange [-2:26]
set yrange [0.78:0.86]
set ytic 0.05 nomirror
set xtic 10 nomirror
unset xtic
unset key

## top ##
set tmargin at screen 0.95
set bmargin at screen 0.71
set border 14


set arrow from -2.5,0.778 to -1.5,0.782 nohead lw 1
set arrow from -2.5,0.7713 to -1.5,0.7753 nohead lw 1

set arrow from 25.5,0.778 to 26.5,0.782 nohead lw 1
set arrow from 25.5,0.7713 to 26.5,0.7753 nohead lw 1

set ylabel ' '

plot file u 1:3 w boxes lc rgb blue_defined fs solid 0.5 noborder

## btm ##
set tmargin at screen 0.69
set bmargin at screen 0.18
set border 11

set yrange [0:0.17]
set xtic 10 nomirror
set xtic format "%g" 
set xlabel 'Number of photons'
set ylabel 'Detection probability' offset 0,1.5

unset arrow
#set label 1 sprintf("threshold") at 1.5,0.32
#set arrow from 1.5,0 to 1.5,0.2 dt 3 lc rgb 'black' lw 2 nohead 

plot file u 1:3 w boxes lc rgb blue_defined fs solid 0.5 noborder, file u ($1-0.5):2 w steps lc rgb 'red' lw 2 lt 1


unset multiplot
unset output