#!/usr/bin/gnuplot

file = 'state_detection_2018-05-18_250ampunits.timestamp.dat.histo'
#f = 'rabi'
f = 'rabi_2018-06-06.dat'
#f0 = 'ramsey'
f0 = 'ramsey_dark_2018_06_05.dat'
#f1 = 'ramsey_bright'
f1 = 'ramsey_bright_2018_06_05.dat'
f2 = 'echo_dark_2018-06-06.dat'
f3 = 'echo_bright_2018-06-06.dat'



set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm, 11cm
set termoption dash
set output "../state_multi.eps"

set multiplot 
blue_defined = '#0078FF'
blue_defined2 = '#0000FF'
set border linewidth 1.5

## state readout top ##
set label 1 sprintf("(a)") at graph 0.9,0.6 font "Helvetica, 16"
set tmargin at screen 0.97
set bmargin at screen 0.91#0.89
set xrange [-1.5:26]
set yrange [79:87]
set ytic 5 nomirror format "%3g"
set xtic 10 nomirror
unset xtic
unset key

set border 14

set arrow from -1.8,78.8 to -1.2,79.1 nohead lw 1
set arrow from -1.8,77.5 to -1.2,77.8 nohead lw 1

set arrow from 25.7,78.8 to 26.3,79.1 nohead lw 1
set arrow from 25.7,77.5 to 26.3,77.8 nohead lw 1

set ylabel "\n"

plot file u 1:($3*100) w boxes lc rgb 'blue' fs solid 0.5 noborder

## state readout btm ##
set tmargin at screen 0.90#0.883
set bmargin at screen 0.77#0.713
set border 11

set yrange [0:17]
set xtic 10 nomirror
set xtic format "%g" 
set xlabel 'Number of photons' offset 0,0.5
set ylabel "Detection\nprobability (%)" offset 0,1.5

set label 1 sprintf("threshold") at 0.9,19.5 font "Helvetica, 14"
set arrow from 1.56,0 to 1.56,18 dt 3 lc rgb 'black' lw 2 nohead 

plot file u 1:($3*100) w boxes lc rgb 'blue' fs solid 0.5 noborder, file u ($1-0.5):($2*100) w steps lc rgb 'red' lw 2 lt 1

unset arrow
## mid - rabi ##
set label 1 sprintf("(b)") at graph 0.9,0.85 font "Helvetica, 16"
set tmargin at screen 0.67
set bmargin at screen 0.47
set border

set xlabel "Pulse length ({/Symbol m}s)" offset 0,0.5
set ylabel "Probability\nin F=2 (%)" offset 0,0

set xrange [0:62]
set yrange [0:100]
set ytics 25
set xtics 15
set pointsize 0.5
unset bar

a0= 0.40
t0 = 25
y0 = 0.95
tau = 600
rabi(x) = a0 - exp(-x/tau)*a0*cos(2*3.14*x/t0) + y0
fit rabi(x) f u 1:5:6 via a0,t0,y0,tau

plot f u 1:(100*$5):(100*$6) w yerr pt 7 ps 1 lc rgb 'red' lw 2, rabi(x)*100 lc rgb 'red'

## btm - ramsay/echo ##
set label 1 sprintf("(c)") at graph 0.9,0.9 font "Helvetica, 16"
set tmargin at screen 0.38
set bmargin at screen 0.08
set border

set xlabel "Free evolution time {/Symbol t} ({/Symbol m}s)" offset 0,0.5
set ylabel "Probability\nin F=2 (%)"

set xrange [0:1105] #805
set yrange [0:100]
set ytics 50
set xtics 200
set pointsize 0.5
unset bar

a02= 0.52
b02 = -0.4
tau2 = 20
echo(x) = a02 - exp(-x**2/tau2**2)*b02
#fit echo(x) f2 u 1:5:6 via b02,tau2

a03= 0.4251+0.1126
b03 = -0.4
tau3 = 400
echo2(x) = a03 - exp(-x**2/tau3**2)*b03
fit echo2(x) f3 u (2*$1):5:6 via b03,tau3

a0= 0.40
t0 = -180
y0 = 0.15 #0.95
tau = 50
ramsey(x) = a0*(1 - exp(-x/tau) ) + y0
fit ramsey(x) f0 u 1:5:6 via a0,y0,tau

#y0 = 0.52
#ramsey2(x) = a0*(1 + (x/tau)**2 )**(-1.5) + y0
#fit ramsey2(x) f0 u 1:5:6 via a0,tau

set label "{/Symbol p}/2 {/Symbol -} {/Symbol t} {/Symbol -} {/Symbol p}/2" at 60,30 tc rgb 'red' font "Helvetica,14"
set label "3{/Symbol p}/2 {/Symbol -} {/Symbol t} {/Symbol -} {/Symbol p}/2" at 60,75 tc rgb 'red' font "Helvetica,14"
set label "3{/Symbol p}/2 {/Symbol -} {/Symbol t}/2 {/Symbol -} {/Symbol p} {/Symbol -} {/Symbol t}/2 {/Symbol -} {/Symbol p}/2" at 550,30 tc rgb 'blue' font "Helvetica,14"
set label "{/Symbol p}/2 {/Symbol -} {/Symbol t}/2 {/Symbol -} {/Symbol p} {/Symbol -} {/Symbol t}/2 {/Symbol -} {/Symbol p}/2" at 550,75 tc rgb 'blue' font "Helvetica,14"

plot ramsey(x)*100 lc rgb 'red',\
echo2(x)*100 lc rgb 'blue',\
f1 u 1:(100*$5):(100*$6) w yerr ps 0.6 pt 5 lc rgb 'red' lw 2 not,\
f0 u 1:(100*$5):(100*$6) w yerr pt 64 lc rgb 'red' lw 2 not,\
f0 u 1:(100*$5) pt 5 lc rgb 'white' lw 1 not,\
f0 u 1:(100*$5) pt 64 lc rgb 'red' not,\
f2 u (2*$1):(100*$5):(100*$6) w yerr pt 65 lc rgb 'blue' lw 2 not,\
f2 u (2*$1):(100*$5) pt 7 lc rgb 'white' not,\
f2 u (2*$1):(100*$5) pt 65 lc rgb 'blue' not,\
f3 u (2*$1):(100*$5):(100*$6) w yerr ps 0.6 pt 7 lc rgb 'blue' lw 2 not

#echo(x)*100 lc rgb blue_defined,\

unset multiplot
unset output