set term eps font "arial,12" enhanced size 8.6cm,12cm
set output "general_trend_g2x_tau_c_rho_vs_current.eps"

set multiplot

set rmargin at screen 0.8

time_offset = 320 #ns
threshold_current = 37.0

# g2X waterfall plot
set size 1,0.35
set origin 0,0.65
set ylabel "t_{2} - t_{1} (ns)"
set format x "" 
set tics front
#set xlabel "current [mA]"
set cblabel "g^{(2X)}"
set xrange [0:120]
set yrange [-300:300]
set cbrange [0.45:1.05]
set cbtics 0.5,0.1,1.05

# draw dotted line for lasing threshold
set arrow from threshold_current, graph 0 to threshold_current, graph 1 front nohead lc rgb 'black' dt 2

# choice of colors
set palette rgb 34,35,36

plot "current_time_g2X.dat" using 1:($2-time_offset):3 with image title ""


# fraction of coherent against current
set size 1,0.35
set origin 0,0.35
# set xlabel "current (mA)"
set ylabel "{/Symbol r}" enhanced
set xrange [0:120]
set yrange [-0.05:1.05]
set ytics auto
set bars large


plot 'rho_vs_current.dat' using 1:2:3:4 with yerr linestyle 7 ps 0.2 linetype rgb "#0000FF" title "", '' using 1:5:6:7 with yerr linestyle 7 ps 0.2 linetype rgb "#FF0000" title ""
# draw dotted line for lasing threshold
set arrow from threshold_current, graph 0 to threshold_current, graph 1 nohead lc rgb 'black' dt 2



# tau c
set size 1,0.4
set origin 0,0
set xlabel "current (mA)"
set ylabel "{/Symbol t}_c (ns)" enhanced
set xrange [0:120]
set yrange [-10:370]
set ytics auto
set bars large
unset format x

plot 'tau_c_vs_current.dat' using 1:2:3 with yerr linestyle 7 ps 0.2 linetype rgb "#0000FF" title "", '' using 1:2 with lines linetype rgb "#0000FF" title ""
# plot 'tau_c_vs_current.dat' using 1:2 with lines linetype rgb "#0000FF" title ""

# draw dotted line for lasing threshold
set arrow from threshold_current, graph 0 to threshold_current, graph 1 nohead lc rgb 'black' dt 2

unset rmargin

# inset finer measurement
set size 0.4,0.2
set origin 0.4,0.4
unset xlabel 
unset ylabel 
set xrange [36:40]
set yrange [-0.05:1.05]
set ytics (0,0.5,1)
set xtics (36,40)
set bars large

plot 'rho_vs_current_fine.dat' using 1:2:3:4 with yerr linestyle 7 ps 0.2 linetype rgb "#0000FF" title "", '' using 1:5:6:7 with yerr linestyle 7 ps 0.2 linetype rgb "#FF0000" title ""

# draw dotted line for lasing threshold
# set arrow from threshold_current, graph 0 to threshold_current, graph 1 front nohead lc rgb 'black' dt 2

unset multiplot