set term eps font "arial,12" enhanced size 8.6cm,8cm
set output "g2x_g2x0_vs_current.eps"

set multiplot layout 2,1

set rmargin at screen 0.8

time_offset = 320 #ns
threshold_current = 37.0

# g2X waterfall plot
set size 1,0.5
set origin 0,0.5
set ylabel "t_{2} - t_{1} [ns]"
set format x "" 
set tics front
#set xlabel "current [mA]"
set cblabel "g^{(2X)}"
set xrange [34:44]
set yrange [-100:100]
set cbrange [0.45:1.05]
set cbtics 0.5,0.1,1.05

# draw dotted line for lasing threshold
set arrow from threshold_current, graph 0 to threshold_current, graph 1 front nohead lc rgb 'black' dt 2

# choice of colors
set palette rgb 34,35,36

plot "current_time_g2X.dat" using 1:($2-time_offset):3 with image title ""


# fraction of coherent against current
set size 1,0.55
set origin 0,0
set xlabel "current [mA]"
set ylabel "{/Symbol r}" enhanced
set xrange [34:44]
set yrange [-0.05:1.05]
set ytics auto
set bars large
unset format x

plot 'g2x0_vs_current.dat' using 1:(2*(1-$2)):3 with yerr linestyle 1 ps 0 linetype rgb "#FF0000" title ""

# draw dotted line for lasing threshold
set arrow from threshold_current, graph 0 to threshold_current, graph 1 nohead lc rgb 'black' dt 2


unset multiplot