set terminal postscript eps color enhanced font "Helvetica,24" size 15.8cm,9.5cm
unset output
set output "photon_sources.eps"
set multiplot


g(x)=( (x>=-1)? 1.0 : (1/0) )
f_sa(x)=(7.572e-6*exp(-(x-2859)*0.03679))+6.4799e-8 #admittedly this does not reflect the 'best' fit of 26.18ns, but visually they will be very similar and I'm too lazy to update...
f_fwm(x)=(7592.26*exp(-(x-1254)*0.07286))+95.3928

sa_integral=5.4751e-4
fwm_integral=259820
sa_amplitude=1.05e-5
fwm_amplitude=8000
sa_offset=2854
fwm_offset=1255

scalingfactor=0.03

set border 3
set label 1 at -23.5,0.4 "Normalized APD counts" rotate
set xlabel "time (ns)"
set ylabel " "
set xrange [-10:85]
set yrange [0:1]
set xtics nomirror
set format y "%1.2f"
set ytics 0.25, 0.25 nomirror
set label 2 at -13.7,0 "0"
set label 3 at 42,0.27 "{/Symbol t}_{s} = 26.2 ns"
set label 4 at 11,0.63 "{/Symbol t}_{f} = 13.6 ns"
set label 5 at 9,0.88 "Heralded photon from \nfour-wave mixing"
set label 6 at 40,0.52 "Photon from the\nsingle atom"
set style arrow 1 nohead lt 1 lw 2 lc rgb "black"
set arrow 1 from 4,0.73 to 8,0.82 as 1
set arrow 2 from 30,0.22 to 39,0.47 as 1

set lmargin at screen 0.15
set rmargin at screen 0.97
set bmargin at screen 0.17
set tmargin at screen 0.65

plot './pulsedexcitation_MPDdetector_pattern3_20140614_500pstimebin.pro' u ($2-sa_offset):($4/(scalingfactor*sa_integral)) w p pt 6 ps 1.2 lc 1 notitle,\
(g(x)*f_sa(x+sa_offset)/(scalingfactor*sa_integral)) w l lt 1 lc rgb "#C90000" lw 8 notitle,\
'./FWM_monitor_perp_g2.g2' u ($1-fwm_offset):($2/(scalingfactor*fwm_integral)) w p pt 7 ps 1.2 lt 1 lc rgb "blue" notitle,\
(g(x)*f_fwm(x+fwm_offset)/(scalingfactor*fwm_integral)) w l lt 1 lc rgb "#0D0DA3" lw 8 notitle

set lmargin at screen 0.15
set rmargin at screen 0.97
set bmargin at screen 0.71
set tmargin at screen 0.97

set border 3
unset label 1
unset xlabel
set format x ""
set ylabel " "
set yrange [0:1]
#set format y "%1.0e"
set ytics 0.5,0.5 nomirror
unset xtics
#set label 4 at -9.5,0 "0"
unset label 3
unset label 4
unset label 5
unset label 6
unset arrow 1
unset arrow 2
set label 7 at 5,0.7 "Excitation pulse"
set style arrow 2 head filled size screen 0.010,30,0 lw 2
set arrow 3 from -7.5,0.3 to -4.5,0.3 as 2
set arrow 4 from 3,0.3 to 0,0.3 as 2
set arrow 5 from 0,0.6 to 4,0.68 as 1
set label 5 at 4,0.3 "{/Symbol t}_{e} = 3 ns"

plot './NIMtest2_MPDdetector_pattern9_20140618.pro' u ($2-sa_offset+2.5):($5/8e-4) w lp pt 6 ps 1.2 lt 1 lc rgb "#228b22" notitle

unset multiplot
unset output