#set terminal pdfcairo color dashed enhanced font "Helvetica,14" size 12.6cm,8cm
set terminal postscript eps color enhanced font "Helvetica,22" size 12.6cm,8cm
set output 'hom_g2.eps'

#no. of triggers, used for normalising
tperp=32198490;
tpll=24582417;

set xlabel "Delay between detection events {/Symbol D}t_{ab} (ns)"
set ylabel "Coincidence probability" offset graph -0.055,0

set label 1 at -188,4.04 "4 {/Symbol=30 \327}10^{-6}"
set xtics autofreq nomirror
set mxtics 2
unset ytics
set ytics format ""
set ytics 1 nomirror ("0" 0, "1" 1,"2" 2,"3" 3, "" 4) offset graph -0.04,0
set yrange [0:4.5]
set bars 0
set border 3
set key spacing 1.5
set key at 155,4.5 font "Helvetica,22"
#unset key

set style arrow 1 nohead lt 1 lw 2 lc rgb "black"
#set arrow from -10,3.3 to -40,4 as 1
#set arrow from -30,1.1 to -50,2.5 as 1
#set label 2 at -125,4.25 "Perpendicular polarizations\n        (non-interfering)" font "Helvetica, 18"
#set label 3 at -120,2.75 "Parallel polarizations\n        (interfering)" font "Helvetica, 18"

#b=9.963e-7;et=0.000272;b2=9.263e-7 #background fit using average value in window from +200 to +700ns.
#b=9.804e-7;et=0.000272;b2=8.981e-7 #background fit using average value in window from +450 to +700ns.
b=9.8044e-7;et=0.0002774;c=3.258;b2=8.981e-7;et2=0.0002813 #from python fitting program, with y offsets from mathematica

plot [-150:150] 'g2_delay_0_10nstimebin.dat' u ($1+c):($2*1e6/tpll):(sqrt($2)*1e6/tpll) w yerrorbars lt 1 lw 2 pt 6 ps 1.5 title "G_{||} , interfering",\
'g2_perp_10nstimebin.dat' u ($1+c):($2*1e6/tperp):(sqrt($2)*1e6/tperp) w yerrorbars lt 1 lw 2 pt 7 ps 1.5 lc rgb "blue" t 'G_{{/Symbol \136 }}, non-interfering',\
'g2_theory_perp.dat' u ($1):((b+et*$2)*1e6) w l lc rgb "blue" lt 1 lw 3 notitle,\
'g2_theory_0n.dat' u ($1):((b+et*$2)*1e6) w l lc rgb "red" lt 1 lw 3 notitle
#'g2_delay_0.dat' u ($1):($2*1e7/tpll):(sqrt($2)*1e7/tpll) w l lt 2 lw 1 lc rgb "red" notitle,\
#'g2_perp.dat' u ($1):($2*1e7/tperp):(sqrt($2)*1e7/tperp) w l lt 2 lw 1 lc rgb "#220000FF" notitle