#

set terminal postscript eps enhanced color font "Helvetica,16" size 8cm,7.5cm
set output 'combined_field.eps'
#set terminal wxt enhanced font "Helvetica,12"

unset label
set multiplot

# Upper plot
set origin 0,0
set format x ""
set xtics 20 nomirror
set ytics 0.02 nomirror

set xlabel ""
set origin 0,0.515
set size 1,0.485

f(x)=b+a*exp(-(x-x0)/c)
a= 0.0372311
b=1.00027
c=7.22791
x0=0

set label 2 "(a)" at -90,1.055

plot [-100:100][0.988:1.065] 'sqsum_error_795.dat' u ($1-103):($2/5.9e-6):($3/5.9e-6) every 4 w yerrorbars pt 7 ps .8 notitle,x >= -2 ? f(x):1/0 notitle lc rgb "black" lw 3


# Lower plot
f(x)=b+a*exp((x-x0)/c)

a=0.0662522
b=1.00117
c=7.40521
x0=0
set origin 0,0
set size 1,0.585
set format x "%2.0f"

set xtics 20 nomirror
set ytics 0.02 nomirror


set xlabel "Time from trigger t (ns)"
set label 1 "Normalized variance of homodyne current  {/Symbol \341 D}{/Helvetica-Italic I^{{ } 2}} {/Symbol \361}" at first -135, first 0.985 rotate by 90


# unset label 1
set label 2 "(b)" at -90,1.055


plot [-100:100][0.988:1.065] 'sqsum_error_762.dat' u ($1-113):($2/3.38e-06):($3/3.38e-06) every 4 w yerrorbars pt 6 ps .8 lc rgb "blue" notitle, x <= 10 ?  f(x): 1/0 notitle lc rgb "black" lw 3