set terminal postscript enhanced eps color size 8.6cm,8.6cm font "Helvetica,16pt"
set output "bandwidth_new.eps"

# Data file : bandwidth_new.dat
# 	col 1 : Detuning
#	col 2 : Measured coincidences (Heralded)
#	col 3 : coincidences corrected for losses 
#	col 4 : Measured 795 singles
#	col 5 : Error in col 3 propagated from losses and statistical error of col 2
#	col 6 : statistical error of col 4
#	col 7 : error in x due to frequency uncertainity from voltage supplied to piezo
#set terminal wxt enhanced font "Helvetica,16"

unset label
set multiplot

T(x)=B+(A/del)*((sqrt(1+F))/(1+(F*(sin(3.14*(x-x0)*1e6/del))**2)));

A=2.25494e11; x0=0; F=148613; B=800; del=12.8e9;
set size 1,0.34
set origin 0,0.37
set ytics 2000
# setting the format here the same for both plots ensures that the
# y axis text uses the same space in both plots, and ensures that the
# axes and the text is aligned. the %4.0f format is chosen to hold integer
# numbers up to four decimals
set format y "%4.0f"
set format x ""
set ylabel font "Helvetica,16" "Unheralded \n idler events"
#set xlabel font "Helvetica,18" "Detuning (MHz)"
set xtics 10
set xlabel ""
#Added 2.09381 MHz to x-axis to have peak at 0 MHz. 0.153 MHz/mV is piezo transfer function. 800 dark counts in 1 min.
plot [-50:50][500:8200] 'bandwidth_new.dat' u 1:4:7:(sqrt($4)) w xyerrorbars notitle pt 5 ps 0.5, T(x) notitle lw 2 lc rgb "blue"

A=2.61943e10; x0=0.66; F=83347; B=0; del=12.8e9;

set xlabel ""
set format x ""
set size 1,0.34
set origin 0,0.66
set ytics 150
set ylabel font "Helvetica,16" "Heralded \n idler events"
#set label font "Helvetica,16" "(a)" at first -35, first 600
#set label font "Helvetica,16" "(b)" at first -35, first -200
plot [-50:50][10:700] 'bandwidth_new.dat' u 1:2:7:(sqrt($2)) w xyerrorbars notitle pt 5 ps 0.5, T(x) notitle lw 2 lc rgb "blue"


T(x)=B+(A/del)*((sqrt(1+F))/(1+(F*(sin(3.14*(x-x0)/del))**2)));
A=97327.2; x0=0; F=282922; B=875.546; del=12.8e3
set size 1,0.42
set origin 0,0
set format x "%2.0f"
set ytics 1500
set xlabel font "Helvetica,16" "Detuning (MHz)"
set ylabel font "Helvetica,16" "Non-Collective \n decay events"
fit T(x) 'bandwidth_new.dat' u 1:($4-$3):(sqrt($5**2+$6**2)) via A,B,F
plot [-50:50][500:5600] 'bandwidth_new.dat' u 1:($4-$3):7:(sqrt($5**2+$6**2)) w xyerrorbars pt 5 ps 0.5 notitle, T(x) lw 2 lc rgb "blue" notitle

unset multiplot