#!/usr/bin/gnuplot
infile1 = 'histo_no_th.dat'
infile2 = 'histo_bi.dat'

set terminal postscript eps color enhanced solid font "Helvetica,23" size 20cm, 9cm
set output "hist.eps"
set termoption dash
#################################
#######
####GENERAL SETTINGS####
set border linewidth 1.5
set samples 5000
set multiplot 
set pointsize 1.5
unset bar
unset key
set style fill solid 0.3 noborder

###########################
#####     ONESIDE SPEC       #####
#first cycle
set xrange [0:190]
set yrange [0:38000]
set ytics 10000 nomirror

set xtics 50 nomirror out offset 0,0.2
set ylabel 'Occurences' # offset 0,1
set xlabel 'Photons' offset 0,0.7

set title "\nFirst probe cycle"
set lmargin at screen 0.15
set rmargin at screen 0.40
set label 1 sprintf("(a)") at graph -0.1,1.1 font "Helvetica, 24"

plot infile1  u 1:($11) lc -1 with boxes , '' u 1:($10) lt 1 lc rgb 'black' lw 3 with steps	

#second probe

set lmargin at screen 0.42
set rmargin at screen 0.67

unset ylabel
set ytics format " "
set title "\n Second probe cycle"
set arrow from 70,0 to 70,33000 lt 3 lc rgb 'black' lw 4 nohead 
set arrow from 70,25000 to 30,25000 lc rgb 'black' lw 1 
set arrow from 70,26000 to 110,26000 lc rgb 'black' lw 1 
set label 1 sprintf("(b)") at graph -0.1,1.1 font "Helvetica, 24"
set label 2 "threshold" at graph 0.2,0.925 
set label 3 "keep" at graph 0.13,0.612 
set label 4 "discard" at graph 0.39,0.74 

plot infile1  u 1:($13) lc -1 with boxes , '' u 1:($12) lt 1 lc rgb 'black' lw 3 with steps	


set lmargin at screen 0.73
set rmargin at screen 0.98
unset arrow
unset label 

set title "First probe cycle\nconditioned on second cycle" 
set ytics format "%g"
set yrange [0:190]
set ytics 50 nomirror
set label 1 sprintf("(c)") at graph -0.15,1.1 font "Helvetica, 24"

plot infile2  u 1:($7) lc -1 with boxes , '' u 1:($6) lt 1 lc rgb 'black' lw 3 with steps	



unset multiplot   
unset output