set terminal postscript eps color enhanced solid font "Helvetica,20" size 10cm, 7cm
set output 'field.eps'

f1 = 'field_out_2d_u=exp.dat'
f2 = 'field_out_2d_u=3.dat'
#f2 = 'tmp.dat'

stats f1 u 5
max1=STATS_max
min1=STATS_min
stats f2 u 5
max2=STATS_max
min2=STATS_min
lam1=0.22
lam2=0.70

set pm3d map
set size ratio -1
set palette rgb 33,13,10 #rainbow
#set palette rgb 21,22,23 #hot
#set palette rgb -34,-35,-36; 

set multiplot
set xtics 2 nomirror out
set ytics 1 nomirror out
#set cbtics 1 nomirror
set tics scale 0.2
set xrange[-2.8:2.8]
set yrange[-1.7:1.7]
set xlabel 'z ({/Symbol m}m)'
set ylabel 'x ({/Symbol m}m)'
#set cblabel '{/Symbol L}' offset -1,0
unset key
#set border 3

############top
set tmargin at screen 0.9
set bmargin at screen 0.5

#topleft
set lmargin at screen 0.12
set rmargin at screen 0.44
set title 'One-sided' offset 0,-0.5
set cbrange [0:lam1]
unset colorbox
unset xlabel
unset xtics
set label 1 sprintf("{/:Bold a}") at graph -0.12,1.15 font "Helvetica, 24"
splot f1 u 1:2:(($4-min1)/max1*lam1) every 30 not 

#topright
set lmargin at screen 0.51
set rmargin at screen 0.83
set title '4Pi'
set cbtics (0,lam1) offset -0.5,0
set colorbox user origin 0.87,0.6 size 0.015,0.2
unset ylabel
unset ytics
set label 1 sprintf("{/:Bold b}") at graph -0.12,1.15 font "Helvetica, 24"
set label 2 sprintf("{/Symbol L}") at graph 1.11,1 font "Helvetica, 20"
splot f1 u 1:2:(($5-min1)/max1*lam1) every 30 not

############btm
set tmargin at screen 0.52
set bmargin at screen 0.12
set ylabel 'x ({/Symbol m}m)'
set xlabel 'z ({/Symbol m}m)' offset 0,1
set cbrange [0:lam2]
set cbtics (0,lam2)
set tics scale 0.2
set xtics 2 nomirror out offset 0,0.5
set ytics 1 nomirror out 

#btmleft
set lmargin at screen 0.12
set rmargin at screen 0.44
set title ''
unset colorbox
set label 1 sprintf("{/:Bold c}") at graph -0.12,1.15 font "Helvetica, 24"
unset label 2
splot f2 u 1:2:(($4-min2)/max2*lam2) every 30 not

#btmright
set lmargin at screen 0.51
set rmargin at screen 0.83
set colorbox user origin 0.87,0.22 size 0.015,0.2
unset ylabel
unset ytics
set label 1 sprintf("{/:Bold d}") at graph -0.12,1.15 font "Helvetica, 24"
set label 2 sprintf("{/Symbol L}") at graph 1.11,1 font "Helvetica, 20"
splot f2 u 1:2:(($5-min2)/max2*lam2) every 30 not

unset multiplot
unset output
#pause -1