#!/usr/bin/gnuplot
infile = 'sum/g2sum_5ns.dat'
#infile = 'sum/g2sum_10ns.dat'
infile2 = 'sum/g2_min.dat'
set terminal postscript eps color enhanced solid font "Helvetica,20" size 20cm,9cm
#set term pdf
#set term pngcairo
set output "g2.eps"

set border linewidth 1.5
set samples 5000
set multiplot 
unset bar
unset key
set title ' '

#####  ####

#set lmargin at screen 0.60
#set rmargin at screen 0.98
set lmargin at screen 0.08
set rmargin at screen 0.46

delay = 482.5
gamma0 = 2*pi*7 *1e-3
lam = 0.08077
yoffset = 0

P = 2*lam/(1-2*lam)
g2_theory(x) = exp(-abs(x)*gamma0) * (P**2 - exp(abs(x)*gamma0/2) )**2  + yoffset

## correction for motion induced bunching
y0=1
amp=0.0191
tau=712 
exp_decay(x) =  (  x > 0 ) ?  amp*exp(-x/tau ) + 1 : amp*exp(x/tau ) + 1 

set xlabel "Time {/Symbol t} (ns)"
set ylabel 'g^{(2)}({/Symbol t})' offset 2,0
set pointsize 1
set xrange [-231:231]
set yrange [0.917:1.024]
set ytics 0.92,0.04,1 nomirror
set xtics 100 nomirror

set label 1 sprintf("(a)") at graph -0.2,1.1 font "Helvetica, 24"

plot infile u ($1-delay):($6/exp_decay($1-delay)):5 w ye pt 7 lw 2 lc rgbcolor "#00c000" , \
g2_theory(x) lc rgb "black"  lw 3 not
#'' u ($1-delay)/:($6/exp_decay($1-delay)) w l lc rgbcolor "#00c000"

#################################
#######

#set lmargin at screen 0.08
#set rmargin at screen 0.46
set lmargin at screen 0.60
set rmargin at screen 0.98


g2_0(x) =  ((2*x/(1-2*x))**2 - 1 )**2 

set xrange [0:0.33]
set yrange [0:3]
set ytics 1 nomirror
set xtics 0.1 nomirror
set xlabel "Coupling efficiency {/Symbol L}"
unset ylabel
set ylabel 'g^{(2)}(0)' #offset 1.5,0

set label 1 sprintf("(b)") at graph -0.15,1.1 font "Helvetica, 24"
set object 1 rect from 0,0.7 to 0.11,1.05  back fc rgb 'light-gray' fs solid noborder
set arrow from 0.08,1.1 to 0.15,1.6 lc rgb 'black' lw 1 

plot g2_0(x) lc rgb "black"  lw 3 not


###########################
#####      inset      #####
set border linewidth 1.5
#set border 15
unset object 1
unset arrow
#set lmargin at screen 0.2
#set rmargin at screen 0.35
set lmargin at screen 0.72
set rmargin at screen 0.87
set tmargin at screen 0.8
set bmargin at screen 0.6


set xtics 0.1 nomirror
set ytics 0.1 nomirror

unset ylabel
unset xlabel
unset label

set xrange [0:0.101]
set yrange [0.87:1.01]


plot g2_0(x) lc rgb "black" lw 1.5 not, infile2 u 1:($8/exp_decay(0)):7 w ye pt 7 ps 1.0 lw 2  lc rgb "#00c000", '' u 1:($8/exp_decay(0)) w l lc rgb "#00c000"




unset multiplot
unset output
pause -1