# This script should display the three signals from the pulse generator that
# prepares the exponential pulse

set terminal postscript eps color enhanced \
    size 8.6cm, 7cm font "Helvetica,16pt"
set output "pulsegen_traces.eps"

# allow for three plots in one graph
set multiplot

set datafile separator ","

set xrange [-900:900]

#common format in y tics so that traces are aligned
set format y "%4.0f"

set grid xtics ytics

#Output trace

set size 1, 0.52
set origin 0, 0
set xlabel "{/Helvetica-Oblique t} / ns"
set yrange [-30:340]

set ylabel "{/Helvetica-Oblique V_{out}} / mV"
plot 'raw_data_files/C120120131-pulsegen00000.txt' every 5\
     using ($1*10**9):($2*1000) w l lc rgbcolor "blue" notitle

#basis voltage
set size 1, 0.32
set origin 0, 0.45
set ylabel "{/Helvetica-Oblique V_{BE}} / mV"
set ytics 200
set format x ""
set yrange [-100:900]
set xlabel ""

plot 'raw_data_files/C220120131-pulsegen00000.txt' every 5\
     using ($1*10**9):(5100-$2*1000) w l lc rgbcolor "dark-green" notitle

# NIM pulse
set size 1, 0.3
set origin 0, 0.7

set ylabel "{/Helvetica-Oblique V_P} / mV"
set format x ""
set yrange [-990:0]
set ytics 250

plot 'raw_data_files/C320120131-pulsegen00000.txt' every 5\
     using ($1*10**9):($2*1000) w l notitle