#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,20" size 12cm,6.5cm
set output 'state_detection.eps'


bm = 0.202
lm = 0.12
rm = 0.95
gap = 0.03
size = 0.73
y1 = 0.0; y2 = 26; y3 = 67; y4 = 72

set multiplot
set colorsequence classic
set boxwidth 1 relative
set style fill transparent solid 0.5 noborder
set xlabel 'Number of photons'
set border 1+2+8
set xtics nomirror
set ytics nomirror
set ytics 5
set lmargin at screen lm
set rmargin at screen rm
set bmargin at screen bm
set tmargin at screen bm + size * (abs(y2-y1) / (abs(y2-y1) + abs(y4-y3) ) )
unset key

set yrange [y1:y2]
plot [-1:35] 'histo.txt' u 1:($3/3374*100) w boxes ls 3 lc 3, '' u ($1+0.5):($2/3374*100) w fsteps ls 1 lw 2 lc 1

set arrow from 2.5,40 to 2.5,61 nohead ls 2 lc 7 lw 3 dt 2

set label "threshold" at 2,62.5 font "Helvetica,20" #18

unset xtics
unset xlabel
set border 2+4+8
set bmargin at screen bm + size * (abs(y2-y1) / (abs(y2-y1) + abs(y4-y3) ) )+gap
set tmargin at screen bm + size + gap
set yrange [y3:y4]

set label 'Detection probability (%)' at screen 0.03, bm + 0.5 * (size + gap) offset 0,-strlen("Detection probability (%)")/4.0 rotate by 90


set arrow from screen lm - gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1)+abs(y4-y3) ) ) - gap / 4.0 to screen \
lm + gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1) + abs(y4-y3) ) ) + gap / 4.0 nohead

set arrow from screen lm - gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1)+abs(y4-y3) ) ) - gap / 4.0  + gap to screen \
lm + gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1) + abs(y4-y3) ) ) + gap / 4.0 + gap nohead

set arrow from screen rm - gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1)+abs(y4-y3) ) ) - gap / 4.0 to screen \
rm + gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1) + abs(y4-y3) ) ) + gap / 4.0 nohead

set arrow from screen rm - gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1)+abs(y4-y3) ) ) - gap / 4.0  + gap to screen \
rm + gap / 4.0, bm + size * (abs(y2-y1) / (abs(y2-y1) + abs(y4-y3) ) ) + gap / 4.0 + gap nohead

plot [-1:35] 'histo.txt' u 1:($3/3374*100) w boxes ls 3 lc 3, '' u ($1-0.5):($2/3374*100) w fsteps ls 1 lc 1

unset multiplot