# STACK left right
set terminal postscript eps color enhanced solid font "Helvetica,20" size 12cm,13cm
set output 'qubitcoh_1.eps'
set multiplot layout 2, 1 #1, 2
set colorsequence classic

#infile0 = 'data/rabi_2019-02-12.dat'
infile0 = 'data/rabi_2019-12-16.dat'
infile1 = 'data/ramsey_bright_2018-06-06.dat'
infile2 = 'data/spinecho_2019-01-10.dat'
infile3 = 'data/clockstate_spinecho.dat'

unset ylabel
unset xlabel
unset key

# top plot

a0=-0.405
t0 = 12
y0 = 0.926
tau = 700
f0 = 70
rabi(x) = a0 - exp(-x/tau)*a0*cos(2*3.14*x*f0/1000) + y0

fit rabi(x) infile0 u 1:5:6 via a0,f0,y0,tau

set xlabel "Pulse length ({/Symbol m}s)"
set ylabel 'Probability in F=2 (%)' offset 1.7, 0
set ytics 25 nomirror
set xtics 15 nomirror
set pointsize 0.5
set xrange [0:62]
set yrange [0:100]
set lmargin at screen 0.12
set rmargin at screen 0.95
set tmargin at screen 0.98 #0.10 l
set bmargin at screen 0.60 #0.49 r
set samples 1000
plot 100*rabi(x) lc 3 lw 1.5 not, infile0 u 1:(100*$5):(100*$6) w yerr ps 1. pt 7 lc 1 lw 2 not

# bottom plot

f(x) = Af*exp(-x/xf)+Bf
g(x) = Ag*exp(-x**2/xg**2)+Bg
h(x) = Ah*exp(-x**2/xh**2)+Bh
Bf = 50
Bg = 50
Bh = 50
Af = 48.5
Ag = 47.3
Ah = 47.3
xf = 38
xg = 446
xh = 9000

set ylabel "Probability in F=2 (%)" offset 1.7, 0
set xlabel "Free evolution time {/Symbol t} ({/Symbol m}s)"
set xrange [1:20800]
set yrange [45:100]
set ytics 25 nomirror
set xtics 10 nomirror
unset key
set logscale x 10
set tmargin at screen 0.49 #0.60 l
set bmargin at screen 0.10 #0.99 r
set label 1 at 4.5, 70 	#1.5, 50
set label 1 "Ramsey(s)" tc lt 1
set label 5 at 95, 70	#500, 65
set label 5 "Echo(s)" tc lt 3
set label 6 at 1900, 70	#2000,97
set label 6 "Echo(c)" tc lt 7
#set key left bottom
plot infile1 u ($1):(100*$5):(100*$6) w yerr lc 1 ps 1. pt 7 t 'Ramsey(s)',\
f(x) lc 1 lw 2 not,\
infile2 u (2*$1):(100*$5):(100*$6) w yerr lc 3 ps 1. pt 7 t 'Echo(s)',\
g(x) lc 3 lw 2 not,\
infile3 u (2000*$1):(100*$5):(100*$6) w yerr lc 7 ps 1. pt 7 t 'Echo(c)',\
h(x) lc 7 lw 2 not

unset multiplot
pause -1