set terminal postscript eps color enhanced solid font "Helvetica,20" size 12cm,13cm
set colorsequence classic
set output 'noisespectrum.eps'
set multiplot layout 3, 1

i = {0.0,1.0}

infile0='1.69V_f'
infile1='2.0V_f'
infile2='2.7V_f'
infile0_s='sim_conv088.dat'
infile0_st='sim_true088.dat'
infile1_s='sim_conv104.dat'
infile1_st='sim_true104.dat'
infile2_s='sim_conv144.dat'
infile2_st='sim_true144.dat'

unset ylabel
unset xlabel
unset key

conver=(6.626e-34/(1.5*927.4e-26))**2
TtoHz=2.1e10
#
set xrange [1.5:30]
#set yrange [1e-9:3e4]
set logscale x 10
set logscale y 10
set format y "10^{%L}"
set xtics (2.5,5,10,20) nomirror
set ytics nomirror
set format x ""
set lmargin 8
set rmargin 1
set tmargin at screen 0.98
set bmargin at screen 0.71
plot infile0 u ($1/1000):(sqrt($2*conver)/2*TtoHz):(sqrt(abs($3)*conver)/2*TtoHz) w yerr lc 1 ps 0.9 pt 7 t '5 pi',\
infile0_s u ($1/1000):($2*TtoHz) w lines lw 3 lc 3,\
infile0_st u ($1/1000):($2*TtoHz) w lines lw 3 lc 3 dt "."
#
set tmargin at screen 0.66
set bmargin at screen 0.39
set ylabel "Noise spectral density (Hz/{/Symbol @{\140\140}\326}Hz)" offset 0,0
plot infile1 u ($1/1000):(sqrt($2*conver)/2*TtoHz):(sqrt(abs($3)*conver)/2*TtoHz) w yerr lc 1 ps 0.9 pt 7 t '5 pi',\
infile1_s u ($1/1000):($2*TtoHz) w lines lw 3 lc 3,\
infile1_st u ($1/1000):($2*TtoHz) w lines lw 3 lc 3 dt "."
#
unset ylabel
set format x "%.0f"
set tmargin at screen 0.34
set bmargin at screen 0.07
set xlabel "Frequency f (kHz)" offset 0,0.5
plot infile2 u ($1/1000):(sqrt($2*conver)/2*TtoHz):(sqrt(abs($3)*conver)/2*TtoHz) w yerr lc 1 ps 0.9 pt 7 t '15 pi',\
infile2_s u ($1/1000):($2*TtoHz) w lines lw 3 lc 3,\
infile2_st u ($1/1000):($2*TtoHz) w lines lw 3 lc 3 dt "."
unset multiplot
pause -1