set terminal postscript eps color enhanced solid font "Helvetica,20" size 12cm,6cm
set colorsequence classic
#set output 'filtering2.eps'
set output 'filtergraph.eps'
#set multiplot layout 1, 2

i = {0.0,1.0}

set label 1 at 300, 0.57
#set label 1 "{/Symbol t}=1ms" tc lt 7
set label 1 "(b)" tc lt 7
set key at 8600,0.55
set key samplen 2

set xlabel '{/Symbol w}/2{/Symbol p} (Hz)'
set ylabel 'Filter function g_N({/Symbol w}, {/Symbol t})' offset 1.8, 0
set xrange [0:8500]
set xtics 2000 nomirror
set ytics 0.2 nomirror
set samples 1000
fac_mod = 0
f_pdd1(x) = abs(1+exp(i*x)-2*exp(i*0.5*x)*cos(0.5*x*fac_mod))**2/x**2
f_pdd5(x) = abs(1+exp(i*x)-2*(exp(i*0.167*x)-exp(i*0.333*x)+exp(i*0.5*x)-exp(i*0.667*x)+exp(i*0.833*x))*cos(0.5*x*fac_mod))**2/x**2
f_pdd9(x) = abs(1+exp(i*x)-2*(exp(i*0.1*x)-exp(i*0.2*x)+exp(i*0.3*x)-exp(i*0.4*x)+exp(i*0.5*x)-exp(i*0.6*x)+exp(i*0.7*x)-exp(i*0.8*x)+exp(i*0.9*x))*cos(0.5*x*fac_mod))**2/x**2
f_udd5(x) = abs(1+exp(i*x)-2*(exp(i*0.067*x)-exp(i*0.25*x)+exp(i*0.5*x)-exp(i*0.75*x)+exp(i*0.933*x))*cos(0.5*x*fac_mod))**2/x**2
f_udd9(x) = abs(1+exp(i*x)-2*(exp(i*0.0245*x)-exp(i*0.0955*x)+exp(i*0.2061*x)-exp(i*0.3455*x)+exp(i*0.5*x)-exp(i*0.6545*x)+exp(i*0.7939*x)-exp(i*0.9045*x)+exp(i*0.9755*x))*cos(0.5*x*fac_mod))**2/x**2

#set lmargin at screen 0.60
#set rmargin at screen 0.99
plot f_pdd1(x*0.006283) lw 2 dt 1 lc 9 t 'spin echo (1{/Symbol p})',\
f_pdd5(x*0.006283) lw 2 dt 1 lc 1 t '5{/Symbol p} PDD',\
f_pdd9(x*0.006283) lw 2 dt 1 lc 3 t '9{/Symbol p} PDD',\
f_udd5(x*0.006283) lw 2 dt 6 lc 1 t '5{/Symbol p} UDD',\
f_udd9(x*0.006283) lw 2 dt 6 lc 3 t '9{/Symbol p} UDD'
#plot f_pdd9(x)

#unset multiplot
pause -1