# STACK THEM ALL
set terminal postscript eps color enhanced solid font "Helvetica,40" size 12cm,10cm
set colorsequence classic
set output 'echo_sc.eps'

infile0 = 'data/ramsey_bright_2018-06-06.dat'
infile1 = 'data/spinecho_2019-01-10.dat'
infile2 = 'data/clockstate_spinecho.dat'

set ylabel "Probability in F=2 (%)"
set xlabel "Free evolution time {/Symbol t} ({/Symbol m}s)"

set xrange [1:20000]
set yrange [45:100]
set ytics 25
#set xtics 1000
unset key
set logscale x 10

f(x) = Af*exp(-x/xf)+Bf
g(x) = Ag*exp(-x**2/xg**2)+Bg
h(x) = Ah*exp(-x**2/xh**2)+Bh
Bf = 50
Bg = 50
Bh = 50
Af = 48.5
Ag = 47.3
Ah = 47.3
xf = 38
xg = 446
xh = 9000

set label 1 at 1.5, 70.0
set label 1 "Ramsey(s)" tc lt 1
#set label 4 at 2.0, 67
#set label 4 "3{/Symbol p}/2-{/Symbol t}-{/Symbol p}/2" tc lt 1
set label 5 at 45, 70
set label 5 "Echo(s)" tc lt 3
#set label 2 at 58.0, 67.0
#set label 2 "{/Symbol p}/2-{/Symbol t}/2-{/Symbol p}-{/Symbol t}/2-{/Symbol p}/2" tc lt 3
set label 6 at 900, 70
set label 6 "Echo(c)" tc lt 7
#set label 3 at 900.0, 67.0
#set label 3 "{/Symbol p}/2-{/Symbol t}/2-{/Symbol p}-{/Symbol t}/2-{/Symbol p}/2" tc lt 7

#set key left bottom

plot infile0 u ($1):(100*$5):(100*$6) w yerr lc 1 ps 1.2 pt 7 t 'Ramsey (stretched)',\
f(x) lc 1 lw 2 not,\
infile1 u (2*$1):(100*$5):(100*$6) w yerr lc 3 ps 1.2 pt 7 t 'Echo (stretched)',\
g(x) lc 3 lw 2 not,\
infile2 u (2000*$1):(100*$5):(100*$6) w yerr lc 7 ps 1.2 pt 7 t 'Echo (clock)',\
h(x) lc 7 lw 2 not

pause -1