#!/usr/bin/gnuplot

set terminal postscript eps color enhanced solid font "Helvetica,16" size 8.6cm,6cm
set output "../time_scan.eps"

####GENERAL SETTINGS####
set border linewidth 1.5
set samples 5000
set pointsize 1
unset bar
set style fill solid 0.3 noborder
set key samplen 0.1
f0 = 'lin_177MHz_timescan' # data from 2017-06-15
f1 = 'circ_177MHz_timescan' # data from 2017-06-16

blue_defined = '#0078FF'

set xtics nomirror
set ytics nomirror

set xlabel 'PGC duration (ms)'
set ylabel 'Temperature ({/Symbol m}K)'

set label 1 sprintf('{/Symbol s^+}-polarized trap') at graph 0.62,0.77 font "Helvetica, 16"
set label 2 sprintf('{/Symbol p}-polarized trap') at graph 0.64,0.24 font "Helvetica, 16"


a0=50
tau0 = 2
y0 = 10
exp_lin(x) = a0*exp(-x/tau0)+y0
fit exp_lin(x) f0 u 1:2:3 via a0,tau0,y0

a1=50
tau1 = 2
y1 = 10
exp_circ(x) = a1*exp(-x/tau1)+y1
fit exp_circ(x) f1 u 1:2:3 via a1,tau1,y1

set ytics 15
set yrange[00:74]
set xrange[-0:16]
set xtics 5
unset key
plot exp_lin(x) w l lw 2 lc rgb 'red' t '',\
exp_circ(x) w l lw 2 lc rgb blue_defined t '',\
f0 u 1:2:3 w ye lc rgb 'red' pt 5 lw 2 t '{/Symbol p}-trap',\
f1 u 1:2:3 w ye lc rgb blue_defined pt 65 lw 2 t '{/Symbol ^+} trap',\
f1 u 1:2 lc rgb 'white' pt 7 lw 2 not,\
f1 u 1:2 lc rgb blue_defined pt 65 lw 2 not



unset output
pause -1